# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit multilib cmake-multilib git-r3

DESCRIPTION="PulseAudio emulation for ALSA"
HOMEPAGE="https://github.com/i-rinat/apulse"

EGIT_REPO_URI="https://github.com/i-rinat/apulse.git"

LICENSE="MIT LGPL-2.1"
SLOT="0"
KEYWORDS=""

DEPEND="dev-libs/glib:2[${MULTILIB_USEDEP}]
	media-libs/alsa-lib[${MULTILIB_USEDEP}]"
RDEPEND="${DEPEND}"

MULTILIB_CHOST_TOOLS=( /usr/bin/apulse )

src_prepare() {
	cmake-utils_src_prepare

	# Ensure all relevant libdirs are added, to support all ABIs
	DIRS=
	_add_dir() { DIRS="${EPREFIX}/usr/$(get_libdir)/apulse${DIRS:+:${DIRS}}"; }
	multilib_foreach_abi _add_dir
	sed -e "s#@@DIRS@@#${DIRS}#g" "${FILESDIR}"/apulse > "${T}"/apulse || die
}

multilib_src_configure() {
	local mycmakeargs=("-DAPULSEPATH=${EPREFIX}/usr/$(get_libdir)/apulse")
	cmake-utils_src_configure
}

multilib_src_install_all() {
	cmake-utils_src_install
	einstalldocs
	dobin "${T}"/apulse
}
