Add x11-misc/xneur - In-place conversion of text typed in with a wrong

keyboard layout (Punto Switcher replacement) and x11-misc/gxneur - GTK
based GUI for xneur

x11-misc/gxneur/Manifest

@@ -0,0 +1,2 @@
+DIST gxneur-0.9.7.tar.bz2 346336 RMD160 7002b519cb70bd9367b057abfa457d740dc2a3fa SHA1 95e907cbf815dda21b367add88b77a08531a95b8 SHA256 c621eaa576c187448313be72aa4b5a3227565d868d218d4032303f0ce5a19024
+EBUILD gxneur-0.9.7.ebuild 951 RMD160 396489ad7b48e401b245ceb1d875f105cb4d9bcf SHA1 e52d477102f2e79bbb6879ac6d157228645b203c SHA256 49e74e3dc712150d119ffbbd44e57a6f7b95b45ac5c7e3db81db374ce6ee6f71

x11-misc/gxneur/gxneur-0.9.7.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils autotools versionator
+
+DESCRIPTION="GTK based GUI for xneur"
+HOMEPAGE="http://www.xneur.ru/"
+SRC_URI="http://dists.xneur.ru/release-${PV}/tgz/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND=">=x11-misc/xneur-$(get_version_component_range 1-2)
+	 >=x11-libs/gtk+-2.0.0
+	 >=sys-devel/gettext-0.16.1
+	 >=gnome-base/libglade-2.6.0"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.20"
+
+src_prepare() {
+	rm ltmain.sh aclocal.m4	m4/{lt~obsolete,ltoptions,ltsugar,ltversion,libtool}.m4
+	sed -i "s/-Werror -g0//" configure.in || die
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc AUTHORS ChangeLog NEWS || die
+	doicon pixmaps/gxneur.png
+	make_desktop_entry "${PN}" "${PN}" ${PN} "GTK;Gnome;Utility;TrayIcon"
+}

x11-misc/xneur/Manifest

@@ -0,0 +1,2 @@
+DIST xneur-0.9.7.tar.bz2 1044732 RMD160 6b45840aec6ecac6372892f762820bfd9d441ee3 SHA1 d38c6db3f12b88f5a628608460338da0e73ff512 SHA256 1efc137a5954e377785422ccd0db7a1fde4f1609b97b73288b603a5f1b59fc32
+EBUILD xneur-0.9.7.ebuild 2319 RMD160 6a3cf50c4a6625f43fc2ee18cd40789af40e869d SHA1 9d9afb5e2fc8d7314f6cfe58b8b8f86bd04b438b SHA256 598ebe279ea23f23888b13ba04728e781ed8958783ad41e569f907696f1287e6

x11-misc/xneur/xneur-0.9.7.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="In-place conversion of text typed in with a wrong keyboard layout (Punto Switcher replacement)"
+HOMEPAGE="http://www.xneur.ru/"
+SRC_URI="http://dists.xneur.ru/release-${PV}/tgz/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aplay debug gstreamer libnotify nls openal xosd pcre +spell"
+
+# Sound does not works here with media-sound/alsa-utils-1.0.16
+RDEPEND="sys-libs/zlib
+	>=x11-libs/libX11-1.1
+	x11-libs/libXtst
+	gstreamer? ( >=media-libs/gstreamer-0.10.6 )
+	!gstreamer? ( openal? ( >=media-libs/freealut-1.0.1 )
+				  !openal? ( aplay? ( >=media-sound/alsa-utils-1.0.17 ) ) )
+	pcre? ( >=dev-libs/libpcre-5.0 )
+	spell? ( app-text/aspell )
+	xosd? ( x11-libs/xosd )
+	libnotify? ( >=x11-libs/libnotify-0.4.0 )"
+DEPEND="${RDEPEND}
+	gstreamer? ( media-libs/gst-plugins-good
+			media-plugins/gst-plugins-alsa )
+	nls? ( sys-devel/gettext )
+	>=dev-util/pkgconfig-0.20"
+
+src_prepare() {
+	# Fixes error/warning: no newline at end of file
+	find . -name '*.c' -exec sed '${/[^ ]/s:$:\n:}' -i '{}' \;
+	rm ltmain.sh aclocal.m4	m4/{lt~obsolete,ltoptions,ltsugar,ltversion,libtool}.m4
+	sed -i -e "s/-Werror -g0//" configure.in
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use gstreamer; then
+		elog "Using gstreamer for sound output."
+		myconf="--with-sound=gstreamer"
+	elif use openal; then
+		elog "Using openal for sound output."
+		myconf="--with-sound=openal"
+	elif use aplay; then
+		elog "Using aplay for sound output."
+		myconf="--with-sound=aplay"
+	else
+		elog "Sound support disabled."
+		myconf="--with-sound=no"
+	fi
+
+	econf ${myconf} \
+		$(use_with debug) \
+		$(use_enable nls) \
+		$(use_with pcre) \
+		$(use_with spell aspell) \
+		$(use_with xosd) \
+		$(use_with libnotify)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc AUTHORS ChangeLog README NEWS TODO || die
+}
+
+pkg_postinst() {
+	elog "This is command line tool. If you are looking for GUI frontend just"
+	elog "emerge gxneur, which uses xneur transparently as backend."
+
+	ewarn "If you upgraded from <=xneur-0.9.3, you need to remove"
+	ewarn "dictionary files in the home directory:"
+	ewarn " $ rm ~/.xneur/{ru,en,be,etc.}/dict"
+}