Add deadbeef-0.5.1-r1.ebuild

13 years ago · 08f443ae57
parent 5b222e8ba6
commit 08f443ae57
2 changed files with 110 additions and 0 deletions
--- a/media-sound/deadbeef/Manifest
+++ b/media-sound/deadbeef/Manifest
@ -1,2 +1,4 @@
 DIST deadbeef-0.4.4.tar.bz2 2612233 RMD160 c0d8c10f5c69f21c02aba82151d80f1e7bc2ef30 SHA1 7981179dfaa2037d1b1fb803c58853bf5cea8764 SHA256 93547e776f1c67a68236d394a67d0d84478f12ad375a4208e6dbba5972f6ec32
+DIST deadbeef-0.5.1.tar.bz2 2317508 RMD160 3d46d05b0d07fc8c3a515fcbd0c7d8525b199588 SHA1 82cbdeb3cdd5303c75d668d3d238e68b442c6db1 SHA256 449e2933634c8f06dfdac65cd1afbe87a7f97fcd8e541694d6e65fe1941ac18f
 EBUILD deadbeef-0.4.4-r2.ebuild 2850 RMD160 9349a47b04b0393813904bab28e08ef46a55dfb1 SHA1 d6b3262bff17fbb1159717de851e1f4c5e24c2a3 SHA256 39aeac3bc0428714e95fd3d70871bd2b337fd95af22afd7517a7e51c7c4f9fe0
+EBUILD deadbeef-0.5.1-r1.ebuild 2766 RMD160 384fe26cfe2a99f9f535eedf81f52bd478ff05e5 SHA1 0f8d9bad36f4019031fa49be39ad0791c2c06f8b SHA256 bc2c59d4996907b59a0e8c1e5d800ba93de662cec1c76b7639fe21bcae319873
--- a/media-sound/deadbeef/deadbeef-0.5.1-r1.ebuild
+++ b/media-sound/deadbeef/deadbeef-0.5.1-r1.ebuild
@ -0,0 +1,108 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+
+inherit fdo-mime
+
+DESCRIPTION="foobar2000-like music player."
+HOMEPAGE="http://deadbeef.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+LICENSE="GPL-2 ZLIB"
+
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="aac adplug alsa cdda cover curl dts encode ffmpeg flac gme +gtk
+	hotkeys imlib lastfm libnotify libsamplerate m3u mac midi mms mp3
+	musepack nls null oss pulseaudio shellexec sid sndfile supereq threads
+	tta vorbis vtx wavpack zip"
+
+REQUIRED_USE="encode? ( gtk )
+	cover? ( curl )
+	lastfm? ( curl )"
+
+RDEPEND="
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cdda? ( dev-libs/libcdio media-libs/libcddb )
+	cover? (
+		imlib? ( media-libs/imlib2 )
+		!imlib? ( virtual/jpeg media-libs/libpng )
+	)
+	curl? ( net-misc/curl )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	gtk? ( x11-libs/gtk+:2 )
+	hotkeys? ( x11-libs/libX11 )
+	libnotify? ( sys-apps/dbus )
+	libsamplerate? ( media-libs/libsamplerate )
+	midi? ( media-sound/timidity-freepats )
+	mp3? ( media-libs/libmad )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	zip? ( sys-libs/zlib )
+	"
+DEPEND="${RDEPEND}
+	nls? ( virtual/libintl dev-util/intltool )
+	"
+
+src_prepare() {
+	if use midi; then
+		# set default gentoo path
+		sed -e 's;/etc/timidity++/timidity-freepats.cfg;/usr/share/timidity/freepats/timidity.cfg;g' \
+			-i "${S}/plugins/wildmidi/wildmidiplug.c"
+	fi
+}
+
+src_configure() {
+	my_config="$(use_enable nls)
+		$(use_enable threads)
+		$(use_enable null nullout)
+		$(use_enable alsa)
+		$(use_enable oss)
+		$(use_enable gtk gtkui)
+		$(use_enable aac)
+		$(use_enable adplug)
+		$(use_enable cdda)
+		$(use_enable cover artwork)
+		$(use_enable curl vfs-curl)
+		$(use_enable dts dca)
+		$(use_enable encode converter)
+		$(use_enable ffmpeg)
+		$(use_enable flac)
+		$(use_enable gme)
+		$(use_enable hotkeys)
+		$(use_enable imlib artwork-imlib2)
+		$(use_enable lastfm lfm)
+		$(use_enable libnotify notify)
+		$(use_enable libsamplerate src)
+		$(use_enable m3u)
+		$(use_enable mac ffap)
+		$(use_enable midi wildmidi)
+		$(use_enable mms)
+		$(use_enable mp3 mad)
+		$(use_enable musepack)
+		$(use_enable pulseaudio pulse)
+		$(use_enable shellexec)
+		$(use_enable sid)
+		$(use_enable sndfile)
+		$(use_enable supereq)
+		$(use_enable tta)
+		$(use_enable vorbis)
+		$(use_enable vtx)
+		$(use_enable wavpack)
+		$(use_enable zip vfs-zip)
+		--docdir=/usr/share/doc/${PF}"
+
+	econf ${my_config}
+}
+
+src_install() {
+	# Do not compress docs as we need it for deadbeef's help function.
+	PORTAGE_DOCOMPRESS_SKIP+=( "/usr/share/doc/${PF}" )
+
+	emake DESTDIR="${D}" install
+}