diff --git a/x11-misc/compton/Manifest b/x11-misc/compton/Manifest
new file mode 100644
index 000000000..100489929
--- /dev/null
+++ b/x11-misc/compton/Manifest
@@ -0,0 +1 @@
+DIST compton-0.1_beta2.tar.gz 144239 BLAKE2B 993c091aa0eab4171740a26c4ea8e9da66368fbcddbbdf9c466dd2cb2dbe0a685dc6c2027a5b56d08df4fd42d21784dd2cbb7cf56869feb1b74b4854db20a5f8 SHA512 c3a019d90e32559d44e3a4969bcc15a15837db9c9519ce8cc70b1bd3d0cb16d29449f68cc2f6a8d834569c9620ec6533ab85c1586da957c69b1ae341d9584535
diff --git a/x11-misc/compton/compton-0.1_beta2-r1.ebuild b/x11-misc/compton/compton-0.1_beta2-r1.ebuild
new file mode 100644
index 000000000..83b8de1b8
--- /dev/null
+++ b/x11-misc/compton/compton-0.1_beta2-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_7 )
+inherit toolchain-funcs python-r1
+
+DESCRIPTION="A compositor for X, and a fork of xcompmgr-dana"
+HOMEPAGE="https://github.com/chjj/compton"
+SRC_URI="https://github.com/chjj/compton/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="dbus +drm opengl +pcre xinerama"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/libconfig:=
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	dbus? ( sys-apps/dbus )
+	opengl? ( virtual/opengl )
+	pcre? ( dev-libs/libpcre:3 )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xprop
+	x11-apps/xwininfo"
+DEPEND="${COMMON_DEPEND}
+	app-text/asciidoc
+	virtual/pkgconfig
+	x11-base/xorg-proto
+	drm? ( x11-libs/libdrm )"
+
+nobuildit() { use $1 || echo yes ; }
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		tc-export CC
+	fi
+}
+
+src_compile() {
+	emake docs
+
+	NO_DBUS=$(nobuildit dbus) \
+	NO_XINERAMA=$(nobuildit xinerama) \
+	NO_VSYNC_DRM=$(nobuildit drm) \
+	NO_VSYNC_OPENGL=$(nobuildit opengl) \
+	NO_REGEX_PCRE=$(nobuildit pcre) \
+		emake compton
+}
+
+src_install() {
+	NO_DBUS=$(nobuildit dbus) \
+	NO_VSYNC_DRM=$(nobuildit drm) \
+	NO_VSYNC_OPENGL=$(nobuildit opengl) \
+	NO_REGEX_PCRE=$(nobuildit pcre) \
+		default
+	docinto examples
+	dodoc compton.sample.conf dbus-examples/*
+	python_foreach_impl python_newscript bin/compton-convgen.py compton-convgen
+}
diff --git a/x11-misc/compton/metadata.xml b/x11-misc/compton/metadata.xml
new file mode 100644
index 000000000..c269c6f6a
--- /dev/null
+++ b/x11-misc/compton/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>johu@gentoo.org</email>
+		<name>Johannes Huber</name>
+	</maintainer>
+	<use>
+		<flag name="drm">Enable VSync with DRM_IOCTL_WAIT_VBLANK</flag>
+		<flag name="opengl">Enable VSync with SGI_swap_control OpenGL extension</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">chjj/compton</remote-id>
+	</upstream>
+</pkgmetadata>