net-vpn/ocserv: version bump

net-vpn/ocserv/Manifest

@@ -0,0 +1,2 @@
+DIST ocserv-1.2.3.tar.xz 757484 BLAKE2B 7a0026a4125169bfa28693b2b8f5b41377a52c2520ca4dd1b935cf9656d17c3c6e0724e207024eebac415fe9a6025848ea40d905c442f1a897843af2ace46f62 SHA512 27984ff6d671b0b572e1656e46d9ec833007f655468522932620292f8a80d6b90425df8f7aac8ad761322adf89062fe245bac35e5727d4f1fd730e705f265ef7
+DIST ocserv-1.2.3.tar.xz.sig 442 BLAKE2B 8bf125555c8d5ad5587e5dd40838a8cd5047e5bbffbc7bd494444ed4ba2d01618f71875780c6c3562acab1c0755d2159c20648c6375e26f04c89bb06483b59a5 SHA512 4732704858a5b4ad2d08470c206db5b58a089e3a55f1935841f42ff13b8df750bc2e9c9ab93762e092f2e7fd7ea2fa113f7326678b78557fecdc3359f77ce486

net-vpn/ocserv/files/ocserv

@@ -0,0 +1,6 @@
+#!/sbin/openrc-run
+
+command="${RC_PREFIX}/usr/sbin/ocserv"
+pidfile="${RC_PREFIX}/run/${RC_SVCNAME}.pid"
+command_args="--pid-file '${pidfile}'"
+command_args_foreground="--foreground"

net-vpn/ocserv/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>floppym@gentoo.org</email>
+		<name>Mike Gilbert</name>
+	</maintainer>
+	<use>
+		<flag name="otp">Enable support for one-time passwords</flag>
+	</use>
+</pkgmetadata>

net-vpn/ocserv/ocserv-1.2.3.ebuild

@@ -0,0 +1,105 @@
+# Copyright 2019-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+if [[ ${PV} == 9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://gitlab.com/openconnect/ocserv.git"
+else
+	inherit verify-sig
+	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/ocserv.asc"
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-ocserv )"
+	SRC_URI="https://www.infradead.org/ocserv/download/${P}.tar.xz
+		verify-sig? ( https://www.infradead.org/ocserv/download/${P}.tar.xz.sig )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Openconnect SSL VPN server"
+HOMEPAGE="https://ocserv.gitlab.io/www/index.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="geoip kerberos +lz4 otp pam radius +seccomp systemd tcpd test"
+RESTRICT="!test? ( test )"
+
+BDEPEND+="
+	virtual/pkgconfig
+	test? (
+		net-libs/gnutls[tools(+)]
+		net-libs/socket_wrapper
+		net-vpn/openconnect
+		sys-libs/nss_wrapper
+		sys-libs/uid_wrapper
+		pam? ( sys-libs/pam_wrapper )
+	)
+"
+DEPEND="
+	dev-libs/libnl:3=
+	dev-libs/libev:0=
+	>=dev-libs/nettle-2.7:0=
+	dev-libs/pcl:0=
+	dev-libs/protobuf-c:0=
+	>=net-libs/gnutls-3.3.0:0=
+	net-libs/http-parser:0=
+	sys-libs/readline:0=
+	sys-libs/talloc:0=
+	virtual/libcrypt:=
+	geoip? ( dev-libs/geoip:0= )
+	kerberos? ( virtual/krb5 )
+	lz4? ( app-arch/lz4:0= )
+	otp? ( sys-auth/oath-toolkit:0= )
+	pam? ( sys-libs/pam:0= )
+	radius? ( net-dialup/freeradius-client:0= )
+	seccomp? ( sys-libs/libseccomp:0= )
+	systemd? ( sys-apps/systemd:0= )
+	tcpd? ( sys-apps/tcp-wrappers:0= )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	if [[ ${PV} == 9999 ]]; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		--without-root-tests
+		--without-nuttcp-tests
+
+		$(use_enable seccomp)
+		$(use_enable systemd)
+
+		$(use_with geoip)
+		$(use_with kerberos gssapi)
+		$(use_with lz4)
+		$(use_with otp liboath)
+		$(use_with radius)
+		$(use_with tcpd libwrap)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	addwrite /proc
+	default
+}
+
+src_install() {
+	default
+
+	dodoc doc/sample.{config,passwd}
+	use otp && dodoc doc/sample.otp
+
+	doinitd "${FILESDIR}"/ocserv
+
+	if use systemd; then
+		systemd_dounit doc/systemd/socket-activated/ocserv.{service,socket}
+	else
+		systemd_dounit doc/systemd/standalone/ocserv.service
+	fi
+}