dev-python/sphinxcontrib-issuetracker-0.11-r3 build with python 3.7

dev-python/sphinxcontrib-issuetracker/Manifest

@@ -0,0 +1,2 @@
+DIST sphinxcontrib-issuetracker-0.11.tar.gz 30351 BLAKE2B 304526543f5d24cc4b2cc76ea8d242d8942fa54737e3d1f0924e816d24aa4838e054b8af468837447d601cacaae987cd285fc706292b979d29dc84f1dbb77ddd SHA512 fb4a977bea22451a3d90b16821fc2a38ed53b17913666ca250e9aab8bb1726bbdb52fb2b6dbb2ae512a0ca6cc3d33dcddeba758c02c77b099180443d67e147c9
+EBUILD sphinxcontrib-issuetracker-0.11-r3.ebuild 1553 BLAKE2B 3b9f8410516c131abf6065838000006ba344e27b383c15baf434f6317212b2f85bea15614eca0b92a00aadfadd4187743bfd098cbff28af6ae1882c771a14fed SHA512 a499c5c75e87eee4b9667f8764c4d9711f31dd3cb8c73e7b6c57e610bef25a40f6dfe24da3afd50745580edd1a43fb411397df2380d0808764dd8d86bb964aa2

dev-python/sphinxcontrib-issuetracker/sphinxcontrib-issuetracker-0.11-r3.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="Extension to sphinx to create links to issue trackers"
+HOMEPAGE="http://sphinxcontrib-issuetracker.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# test requires network access (bug #425694)
+	rm tests/test_builtin_trackers.py || die
+
+	# Tests from tests/test_stylesheet.py require dev-python/PyQt4[X,webkit]
+	# and virtualx.eclass.
+	rm tests/test_stylesheet.py || die
+
+	# Avoid redundant objects.inv from downloading, sed more lightweight
+	if use doc; then
+		sed -e "s:^intersphinx_mapping:#intersphinx_mapping:" \
+			-e "s:^                       'sphinx':#:" \
+			-i doc/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C doc html
+		HTML_DOCS=( doc/_build/html/. )
+	fi
+}
+
+python_test() {
+	py.test || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}