dev-python/flask-cors-2.1.0-r1 build with python 3.7

dev-python/flask-cors/Manifest

@@ -0,0 +1,2 @@
+DIST flask-cors-2.1.0.tar.gz 28038 BLAKE2B ecba951b0bac645088658ea5dc4947c0eaf9d0adb8f0f70e3a3f68337e008cb04a5efab3cb8139aaddf380f9b59c2524d33a5c5ac851b98446dadff9aa82fc92 SHA512 235162749485588e9112a52a833a43e68ad1737997628dc51cc30358d01837f427ba33872ecb1fff8e821b84c3de0a15a1c89c57f2407ef0cacafae9ca354640
+EBUILD flask-cors-2.1.0-r1.ebuild 1697 BLAKE2B 30c186f3af8a2236516393ba0b1e06f2d5f98a372f333406b165923dd19665b53b9ac4dd49ad841942c7829b72546452c2ee78ddaf7d84d8d4e0cae175750aca SHA512 938d4b60e6a44665327edcae6192815a5d13de12b8aafbf7b6108eb20ea87144d91dcb1840125e930fc67645f298ad048dd28166dc447f12d2a509e9eaa073a9

dev-python/flask-cors/flask-cors-2.1.0-r1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python3_7 )
+
+inherit distutils-r1
+
+MY_PN="Flask-Cors"
+MY_P="${MY_PN}-${PV}"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="https://github.com/wcdolphin/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
+HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.org/project/Flask-Cors/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		${RDEPEND}
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/python-docs-2.7.6-r1:2.7
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}