Перенесён libgnome-keyring-3.10.1

gnome-base/libgnome-keyring/Manifest

@@ -0,0 +1 @@
+DIST libgnome-keyring-3.10.1.tar.xz 428336 SHA256 052cf1121ba823359afe534c425f7e216c6a2b1a2b316dee279dcf9032423772 SHA512 447f24792cf75c746e72f7e714e815f289820ae47f37458e8276eee148529d42f7a2f0a759ca466736e9f6ec46d998c3f7a735aa856db9bbfdf602e369138d7e WHIRLPOOL 7521fb48f5a3e7a5ef1e7421ec082ec864a0314d09783137dad14b36ad42f48dab52e90632d030028e5a80e802ce1d489b8242c1e71e7577876305431890acc8

gnome-base/libgnome-keyring/libgnome-keyring-3.10.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome-keyring/libgnome-keyring-3.10.1.ebuild,v 1.11 2014/04/21 10:29:18 ago Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit gnome2 python-any-r1 vala
+
+DESCRIPTION="Compatibility library for accessing secrets"
+HOMEPAGE="http://live.gnome.org/GnomeKeyring"
+
+LICENSE="LGPL-2+ GPL-2+" # tests are GPL-2
+SLOT="0"
+IUSE="debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris"
+
+RDEPEND="
+	>=sys-apps/dbus-1
+	>=gnome-base/gnome-keyring-3.1.92
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+
+	# FIXME: Remove silly CFLAGS, report upstream
+	sed -e 's:CFLAGS="$CFLAGS -g:CFLAGS="$CFLAGS:' \
+		-e 's:CFLAGS="$CFLAGS -O0:CFLAGS="$CFLAGS:' \
+		-i configure.ac configure || die "sed failed"
+}
+
+src_configure() {
+	gnome2_src_configure $(use_enable vala)
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	dbus-launch emake check || die "tests failed"
+}