calculate-overlay/app-emulation/wine-etersoft-public/wine-etersoft-public-1.0.9.ebuild

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic multilib

DESCRIPTION="MS Windows compatibility layer (WINE@Etersoft public edition)"
HOMEPAGE="http://etersoft.ru/wine"

SRC_URI="ftp://updates.etersoft.ru/pub/Etersoft/WINE@Etersoft/${PV}/sources/tarball/wine-etersoft-public-${PV}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="cups dbus debug hal jpeg lcms ldap nas ncurses scanner xml X cifs"
RESTRICT="nomirror"


RDEPEND=">=media-libs/freetype-2.0.0
	!app-emulation/wine
	cifs? ( >=app-emulation/etersoft-cifs-1.50c )
	media-fonts/corefonts
	ncurses? ( >=sys-libs/ncurses-5.2 )
	dbus? ( sys-apps/dbus )
	hal? ( sys-apps/hal )
	X? (
		x11-libs/libXcursor
		x11-libs/libXrandr
		x11-libs/libXi
		x11-libs/libXmu
		x11-libs/libXxf86vm
		x11-apps/xmessage
	)
	nas? ( media-libs/nas )
	cups? ( net-print/cups )
	jpeg? ( media-libs/jpeg )
	ldap? ( net-nds/openldap )
	lcms? ( media-libs/lcms )
	xml? ( dev-libs/libxml2 dev-libs/libxslt )
	>=media-gfx/fontforge-20060703
	scanner? ( media-gfx/sane-backends )
	amd64? (
		>=app-emulation/emul-linux-x86-xlibs-2.1
		>=app-emulation/emul-linux-x86-soundlibs-2.1
		>=sys-kernel/linux-headers-2.6
	)"
DEPEND="${RDEPEND}
	X? (
		x11-proto/inputproto
		x11-proto/xextproto
		x11-proto/xf86vidmodeproto
	)
	sys-devel/bison
	sys-devel/flex"


src_unpack() {
	unpack ${A}
	cd "${WORKDIR}"/wine-${PV}/

	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in
	sed -i '/^MimeType/d' tools/wine.desktop || die #117785
	
}

config_cache() {
	local h ans="no"
	use $1 && ans="yes"
	shift
	for h in "$@" ; do
		[[ ${h} == *.h ]] \
			&& h=header_${h} \
			|| h=lib_${h}
		export ac_cv_${h//[:\/.]/_}=${ans}
	done
}

src_compile() {
	export LDCONFIG=/bin/true
	use scanner || export ac_cv_path_sane_devel="no"
	config_cache cups cups/cups.h
	config_cache nas audio/audiolib.h audio/soundlib.h
	config_cache xml libxml/parser.h libxslt/pattern.h libxslt/transform.h
	config_cache ldap ldap.h lber.h
	config_cache dbus dbus/dbus.h
	config_cache hal hal/libhal.h
	config_cache jpeg jpeglib.h
	config_cache lcms lcms.h

	strip-flags

	use amd64 && multilib_toolchain_setup x86

	cd "${WORKDIR}"/wine-${PV}/
	
	econf \
		CC=$(tc-getCC) \
		--sysconfdir=/etc/wine \
		--disable-opengl \
		--with-x \
		$(use_enable debug trace) \
		$(use_enable debug) \
		|| die "configure failed"

	emake -j1 depend || die "depend"
	emake all || die "all"
}

src_install() {
	cd "${WORKDIR}"/wine-${PV}/
	make DESTDIR="${D}" install || die
	dodoc ANNOUNCE AUTHORS ChangeLog README
	dodir /etc/init.d
	make -C etersoft install DESTDIR=${D} prefix=/usr initdir=/etc/init.d sysconfdir=/etc
	rm -f ${D}/wine{,.outformat}
	rm -f ${D}/usr/bin/wine-glibc
	dosym /usr/bin/wine-pthread  /usr/bin/wine-glibc
	cp "${FILESDIR}"/*.fon ${D}/usr/share/wine/fonts/
	cp "${FILESDIR}"/*.ttf ${D}/usr/share/wine/fonts/
	cp "${FILESDIR}"/wine.init ${WORKDIR}/wine
	doinitd ${WORKDIR}/wine
}

pkg_postinst() {
	elog "~/.wine/config is now deprecated.  For configuration either use"
	elog "winecfg or regedit HKCU\\Software\\Wine"
	elog ""
	elog "Use wine for initial user enviroment or wine --update."
}