You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
48 lines
1.3 KiB
48 lines
1.3 KiB
# Copyright 1999-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{9..11} )
|
|
|
|
inherit gnome.org meson python-single-r1 xdg
|
|
|
|
DESCRIPTION="OS-native connector counterpart for GNOME Shell browser extension"
|
|
HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShellIntegration"
|
|
|
|
LICENSE="GPL-3+"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 x86"
|
|
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
|
|
DEPEND="${PYTHON_DEPS}
|
|
$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
|
|
"
|
|
RDEPEND="${DEPEND}
|
|
gnome-base/gnome-shell
|
|
"
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
python_fix_shebang "${D}/usr/bin/${PN}"
|
|
python_fix_shebang "${D}/usr/bin/${PN}-host"
|
|
python_optimize
|
|
|
|
if [[ $(get_libdir) != "lib" && "${SYMLINK_LIB}" != yes ]]; then
|
|
# Workaround www-client/firefox-bin manifests location
|
|
# Bug: https://bugs.gentoo.org/643522
|
|
insinto /usr/lib/mozilla/native-messaging-hosts
|
|
for id in chrome_gnome_shell browser_connector; do
|
|
doins "${ED}/usr/$(get_libdir)/mozilla/native-messaging-hosts/org.gnome.${id}.json"
|
|
done
|
|
fi
|
|
}
|
|
|
|
pkg_postinst() {
|
|
xdg_pkg_postinst
|
|
|
|
elog "Please note that this package provides OS-native connector only."
|
|
elog "You can install browser extension using link provided at"
|
|
elog "https://extensions.gnome.org website."
|
|
}
|