You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
91 lines
2.2 KiB
91 lines
2.2 KiB
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
ECM_TEST="true"
|
|
KFMIN=5.106.0
|
|
QTMIN=5.15.9
|
|
PYTHON_COMPAT=( python3_{10..11} )
|
|
inherit ecm gear.kde.org python-single-r1
|
|
|
|
DESCRIPTION="Cross-platform web browser using QtWebEngine"
|
|
HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm64 ~x86"
|
|
IUSE="dbus kde python +X"
|
|
|
|
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
|
RESTRICT="test" # bug 653046
|
|
|
|
COMMON_DEPEND="
|
|
dev-libs/openssl:0=
|
|
>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
|
|
>=dev-qt/qtgui-${QTMIN}:5
|
|
>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
|
|
>=dev-qt/qtprintsupport-${QTMIN}:5
|
|
>=dev-qt/qtsql-${QTMIN}:5[sqlite]
|
|
>=dev-qt/qtwebchannel-${QTMIN}:5
|
|
>=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
|
|
>=dev-qt/qtwidgets-${QTMIN}:5
|
|
>=kde-frameworks/karchive-${KFMIN}:5
|
|
virtual/libintl
|
|
dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
|
|
kde? (
|
|
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
|
>=kde-frameworks/kcrash-${KFMIN}:5
|
|
>=kde-frameworks/kio-${KFMIN}:5
|
|
>=kde-frameworks/kjobwidgets-${KFMIN}:5
|
|
>=kde-frameworks/kwallet-${KFMIN}:5
|
|
>=kde-frameworks/purpose-${KFMIN}:5
|
|
)
|
|
python? (
|
|
${PYTHON_DEPS}
|
|
$(python_gen_cond_dep "
|
|
>=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
|
|
>=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
|
|
")
|
|
)
|
|
X? (
|
|
>=dev-qt/qtx11extras-${QTMIN}:5
|
|
x11-libs/libxcb:=
|
|
x11-libs/xcb-util
|
|
)
|
|
"
|
|
DEPEND="${COMMON_DEPEND}
|
|
>=dev-qt/qtconcurrent-${QTMIN}:5
|
|
"
|
|
if [[ ${KDE_BUILD_TYPE} != live ]]; then
|
|
DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
|
|
fi
|
|
RDEPEND="${COMMON_DEPEND}
|
|
>=dev-qt/qtsvg-${QTMIN}:5
|
|
"
|
|
BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
|
|
|
|
PATCHES=( "${FILESDIR}/${PN}-23.07.80-python3.patch" )
|
|
|
|
pkg_setup() {
|
|
use python && python-single-r1_pkg_setup
|
|
ecm_pkg_setup
|
|
}
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DBUILD_KEYRING=OFF
|
|
-DDISABLE_DBUS=$(usex !dbus)
|
|
$(cmake_use_find_package kde KF5Wallet)
|
|
$(cmake_use_find_package kde KF5KIO)
|
|
-DBUILD_PYTHON_SUPPORT=$(usex python)
|
|
-DNO_X11=$(usex !X)
|
|
)
|
|
use python && mycmakeargs+=(
|
|
-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
|
|
-DPython3_INCLUDE_DIR=$(python_get_includedir)
|
|
-DPython3_LIBRARY=$(python_get_library_path)
|
|
)
|
|
ecm_src_configure
|
|
}
|