You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
63 lines
1.8 KiB
63 lines
1.8 KiB
# Copyright 1999-2022 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
ETYPE="headers"
|
|
H_SUPPORTEDARCH="alpha amd64 arc arm arm64 avr32 cris frv hexagon hppa ia64 loong m68k metag microblaze mips mn10300 nios2 openrisc ppc ppc64 riscv s390 score sh sparc x86 xtensa"
|
|
inherit kernel-2
|
|
detect_version
|
|
|
|
PATCH_PV=${PV} # to ease testing new versions against not existing patches
|
|
PATCH_VER="0"
|
|
PATCH_DEV="sam"
|
|
LOONGARCH_PATCH_VER="20220423"
|
|
LOONGARCH_PATCH_DEV="xen0n"
|
|
SRC_URI="${KERNEL_URI}
|
|
${PATCH_VER:+https://dev.gentoo.org/~${PATCH_DEV}/distfiles/sys-kernel/linux-headers/gentoo-headers-${PATCH_PV}-${PATCH_VER}.tar.xz}
|
|
experimental-loong? ( ${LOONGARCH_PATCH_VER:+https://dev.gentoo.org/~${LOONGARCH_PATCH_DEV}/distfiles/linux-loongarch-next-on-${PATCH_PV}-${LOONGARCH_PATCH_VER}.tar.xz} )"
|
|
S="${WORKDIR}/linux-${PV}"
|
|
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
|
|
IUSE+=" experimental-loong"
|
|
|
|
BDEPEND="app-arch/xz-utils
|
|
dev-lang/perl"
|
|
|
|
# bug #816762
|
|
RESTRICT="test"
|
|
|
|
[[ -n ${PATCH_VER} ]] && PATCHES=( "${WORKDIR}"/${PATCH_PV} )
|
|
|
|
src_unpack() {
|
|
# avoid kernel-2_src_unpack
|
|
default
|
|
}
|
|
|
|
src_prepare() {
|
|
# TODO: May need forward porting to newer versions
|
|
use elibc_musl && PATCHES+=(
|
|
"${FILESDIR}"/${PN}-5.10-Use-stddefs.h-instead-of-compiler.h.patch
|
|
"${FILESDIR}"/${PN}-5.15-remove-inclusion-sysinfo.h.patch
|
|
)
|
|
|
|
use experimental-loong && PATCHES+=(
|
|
"${WORKDIR}"/loongarch-next-on-${PATCH_PV}
|
|
)
|
|
|
|
# avoid kernel-2_src_prepare
|
|
default
|
|
}
|
|
|
|
src_test() {
|
|
emake headers_check ${xmakeopts}
|
|
}
|
|
|
|
src_install() {
|
|
kernel-2_src_install
|
|
|
|
find "${ED}" \( -name '.install' -o -name '*.cmd' \) -delete || die
|
|
# delete empty directories
|
|
find "${ED}" -empty -type d -delete || die
|
|
}
|