74 lines
1.4 KiB
Bash
74 lines
1.4 KiB
Bash
|
# Copyright 1999-2021 Gentoo Authors
|
||
|
|
# Distributed under the terms of the GNU General Public License v2
|
||
|
|
|
||
|
|
EAPI=7
|
||
|
|
|
||
|
|
inherit desktop savedconfig toolchain-funcs
|
||
|
|
|
||
|
|
DESCRIPTION="Simple terminal implementation for X"
|
||
|
|
HOMEPAGE="https://st.suckless.org/"
|
||
|
|
SRC_URI="https://dl.suckless.org/st/${P}.tar.gz"
|
||
|
|
|
||
|
|
LICENSE="MIT-with-advertising"
|
||
|
|
SLOT="0"
|
||
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~riscv ~x86"
|
||
|
|
IUSE="savedconfig"
|
||
|
|
|
||
|
|
RDEPEND="
|
||
|
|
>=sys-libs/ncurses-6.0:0=
|
||
|
|
media-libs/fontconfig
|
||
|
|
x11-libs/libX11
|
||
|
|
x11-libs/libXft
|
||
|
|
"
|
||
|
|
DEPEND="
|
||
|
|
${RDEPEND}
|
||
|
|
x11-base/xorg-proto
|
||
|
|
"
|
||
|
|
BDEPEND="virtual/pkgconfig"
|
||
|
|
|
||
|
|
PATCHES=(
|
||
|
|
"${FILESDIR}"/${P}-locale-musl-segfault.patch
|
||
|
|
)
|
||
|
|
|
||
|
|
src_prepare() {
|
||
|
|
default
|
||
|
|
|
||
|
|
sed -i \
|
||
|
|
-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
|
||
|
|
-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
|
||
|
|
-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
|
||
|
|
config.mk || die
|
||
|
|
sed -i \
|
||
|
|
-e '/tic/d' \
|
||
|
|
Makefile || die
|
||
|
|
|
||
|
|
restore_config config.h
|
||
|
|
}
|
||
|
|
|
||
|
|
src_configure() {
|
||
|
|
sed -i \
|
||
|
|
-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
|
||
|
|
config.mk || die
|
||
|
|
|
||
|
|
tc-export CC
|
||
|
|
}
|
||
|
|
|
||
|
|
src_install() {
|
||
|
|
emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
|
||
|
|
|
||
|
|
dodoc TODO
|
||
|
|
|
||
|
|
make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
|
||
|
|
|
||
|
|
save_config config.h
|
||
|
|
}
|
||
|
|
|
||
|
|
pkg_postinst() {
|
||
|
|
if ! [[ "${REPLACING_VERSIONS}" ]]; then
|
||
|
|
elog "Please ensure a usable font is installed, like"
|
||
|
|
elog " media-fonts/corefonts"
|
||
|
|
elog " media-fonts/dejavu"
|
||
|
|
elog " media-fonts/urw-fonts"
|
||
|
|
fi
|
||
|
|
}
|