You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

79 lines
2.6 KiB

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. EAPI=7
  4. DISTUTILS_USE_SETUPTOOLS=no
  5. PYTHON_COMPAT=( python3_{8..10} pypy3 )
  6. PYTHON_REQ_USE='bzip2(+)'
  7. inherit distutils-r1
  8. if [[ ${PV} == *9999 ]]; then
  9. inherit git-r3
  10. EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/portage.git"
  11. S="${WORKDIR}/${P}/repoman"
  12. else
  13. SRC_URI="https://dev.gentoo.org/~zmedico/portage/archives/${P}.tar.bz2
  14. https://github.com/gentoo/portage/compare/285d3ae987a079f32b909c6e6eddde9bc45a4a25...b09b4071151d8e3a81f3576843d00f88eb407799.patch -> ${P}-unit-test-bug-779055.patch
  15. https://github.com/gentoo/portage/commit/e29177fcd2950199afa4f83673c0771afb261123.patch -> ${P}-version-bug-779508.patch
  16. https://github.com/gentoo/portage/commit/2eb3ca092a528e0722e0ca32f616836ed8039936.patch -> ${P}-unit-test-bug-779967.patch"
  17. KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  18. fi
  19. DESCRIPTION="Repoman is a Quality Assurance tool for Gentoo ebuilds"
  20. HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage"
  21. LICENSE="GPL-2"
  22. SLOT="0"
  23. IUSE=""
  24. RDEPEND="
  25. >=sys-apps/portage-3.0.18[${PYTHON_USEDEP}]
  26. >=dev-python/lxml-3.6.0[${PYTHON_USEDEP}]
  27. dev-python/pyyaml[${PYTHON_USEDEP}]
  28. "
  29. DEPEND="${RDEPEND}"
  30. python_prepare_all() {
  31. local patches=(
  32. "${DISTDIR}/${P}-unit-test-bug-779055.patch"
  33. "${DISTDIR}/${P}-version-bug-779508.patch"
  34. "${DISTDIR}/${P}-unit-test-bug-779967.patch"
  35. )
  36. eapply -p2 "${patches[@]}"
  37. distutils-r1_python_prepare_all
  38. }
  39. python_test() {
  40. unset REPOMAN_DEFAULT_OPTS
  41. esetup.py test
  42. }
  43. python_install() {
  44. # Install sbin scripts to bindir for python-exec linking
  45. # they will be relocated in pkg_preinst()
  46. distutils-r1_python_install \
  47. --system-prefix="${EPREFIX}/usr" \
  48. --bindir="$(python_get_scriptdir)" \
  49. --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  50. --htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
  51. --sbindir="$(python_get_scriptdir)" \
  52. --sysconfdir="${EPREFIX}/etc" \
  53. "${@}"
  54. }
  55. pkg_postinst() {
  56. if [[ -z ${REPLACING_VERSIONS} ]]; then
  57. elog ""
  58. elog "This release of repoman is from the new portage/repoman split"
  59. elog "release code base."
  60. elog "This new repoman code base is still being developed. So its API's"
  61. elog "are not to be considered stable and are subject to change."
  62. elog "The code released has been tested and considered ready for use."
  63. elog "This however does not guarantee it to be completely bug free."
  64. elog "Please report any bugs you may encounter."
  65. elog ""
  66. fi
  67. }