You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

59 lines
1.5 KiB

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. EAPI=7
  4. inherit texlive-common
  5. DESCRIPTION="DVI-to-PostScript translator"
  6. HOMEPAGE="http://tug.org/texlive/"
  7. SRC_URI="https://dev.gentoo.org/~zlogene/distfiles/texlive/texlive-${PV#*_p}-source.tar.xz"
  8. TL_VERSION=2021
  9. EXTRA_TL_MODULES="dvips"
  10. EXTRA_TL_DOC_MODULES="dvips.doc"
  11. for i in ${EXTRA_TL_MODULES} ; do
  12. SRC_URI="${SRC_URI} https://dev.gentoo.org/~zlogene/distfiles/texlive/tl-${i}-${TL_VERSION}.tar.xz"
  13. done
  14. SRC_URI="${SRC_URI} doc? ( "
  15. for i in ${EXTRA_TL_DOC_MODULES} ; do
  16. SRC_URI="${SRC_URI} https://dev.gentoo.org/~zlogene/distfiles/texlive/tl-${i}-${TL_VERSION}.tar.xz"
  17. done
  18. SRC_URI="${SRC_URI} ) "
  19. LICENSE="GPL-2"
  20. SLOT="0"
  21. KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  22. IUSE="doc source"
  23. DEPEND=">=dev-libs/kpathsea-6.2.1:="
  24. BDEPEND="virtual/pkgconfig"
  25. S=${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}
  26. src_configure() {
  27. econf --with-system-kpathsea
  28. }
  29. src_install() {
  30. emake DESTDIR="${D}" prologdir="${EPREFIX}/usr/share/texmf-dist/dvips/base" install
  31. dodir /usr/share # just in case
  32. cp -pR "${WORKDIR}"/texmf-dist "${ED}/usr/share/" || die "failed to install texmf trees"
  33. if use source ; then
  34. cp -pR "${WORKDIR}"/tlpkg "${ED}/usr/share/" || die "failed to install tlpkg files"
  35. fi
  36. dodoc AUTHORS ChangeLog NEWS README TODO
  37. }
  38. pkg_postinst() {
  39. etexmf-update
  40. }
  41. pkg_postrm() {
  42. etexmf-update
  43. }