root
9 months ago
parent
469fbba921
commit
7027e33a9a
Binary file not shown.
Binary file not shown.
@ -1,2 +1 @@
|
||||
DIST kontrast-23.04.2.tar.xz 205248 BLAKE2B cf473f952b6c1c9cb6f699fab6ea9dac43d79631d8e9a2e09358187d004fe5f4831b7e9f531204e1537a5f67d6cfb5efcc289fb93e72593dfee2ba81bdf9bafd SHA512 cf99e0a317de4dae7c25433d4e840250e1e493dbeed1f1d2e495bba2ea0c1b399d9e413efe6ae5d30d09fffd2b6be39bea13ef9a6fff974ea63d1dfa2631cb12
|
||||
DIST kontrast-23.04.3.tar.xz 205832 BLAKE2B cd85476a137c19b00fd86686d1adf76ff9942208c5b5f435d352a949f11d1d34c75dbcb7d235869bed5aa2152f19e70e801eb6ab0c8c40350118b2a4ad144407 SHA512 f4c00bcee75999008a227156f169cb642646ff7e4ca2496103502011a6637c35c42d48bdc04aa630f119d03fc4d07cbb3619670fa45e1f03f7bfa9620805c24c
|
||||
|
||||
@ -1,33 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Tool to check contrast for colors to verify they are correctly accessible"
|
||||
HOMEPAGE="https://apps.kde.org/kontrast/"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="5"
|
||||
KEYWORDS="amd64 arm64 ~riscv x86"
|
||||
IUSE=""
|
||||
|
||||
DEPEND="
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
>=dev-qt/qtsql-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kirigami-${KFMIN}:5
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
kde-plasma/xdg-desktop-portal-kde
|
||||
"
|
||||
Binary file not shown.
Binary file not shown.
Binary file not shown.
@ -1,2 +1 @@
|
||||
DIST dolphin-plugins-23.04.2.tar.xz 272640 BLAKE2B 9eb16d5625e2207fc8a301ed8fe6352beedd48f063d139e275b4306a215344163aba90bd1fec3a7f63e2e1cd0692d92af46b910c55dc8fd228a9794f0d6e4a23 SHA512 daffe06e0ad07dd4d5cc93a8cbf362fd54fdf930263b669f54893cfa28d4f838f7cbd8d6f2960c534d367493349b0aa147124718538e0014088e80fb4f6feb5d
|
||||
DIST dolphin-plugins-23.04.3.tar.xz 272912 BLAKE2B f0eb8bbab16d66f1e964131b436af7d3ae8febc26cf4fe394489a978c701ef2f5689bea7daf9eed8d7ef2f1f2bdba000a487cf7f0704ad30bd25e2d403ce5fae SHA512 8f487ba0bcbe561915064247ddb2327c3b7c8fa6ffc5c511d9c9ef37bd4f28a624533ce7a2da2a86b10b65f37915ca10840517872b40c2fd014cead6da5972c8
|
||||
|
||||
@ -1,62 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="false"
|
||||
KDE_ORG_CATEGORY="sdk"
|
||||
KDE_ORG_NAME="dolphin-plugins"
|
||||
MY_PLUGIN_NAME="mountiso"
|
||||
KFMIN=5.106.0
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
|
||||
HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
|
||||
|
||||
LICENSE="GPL-2+"
|
||||
SLOT="5"
|
||||
KEYWORDS="amd64 arm64 ~loong ~ppc64 x86"
|
||||
IUSE=""
|
||||
|
||||
DEPEND="
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=kde-apps/dolphin-${PVCUT}:5
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:5
|
||||
>=kde-frameworks/kconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kio-${KFMIN}:5
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/solid-${KFMIN}:5
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
# kxmlgui, qtnetwork only required by dropbox
|
||||
ecm_punt_qt_module Network
|
||||
ecm_punt_kf_module XmlGui
|
||||
# delete non-${PN} translations
|
||||
find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_${MY_PLUGIN_NAME}=ON
|
||||
-DBUILD_bazaar=OFF
|
||||
-DBUILD_dropbox=OFF
|
||||
-DBUILD_git=OFF
|
||||
-DBUILD_hg=OFF
|
||||
-DBUILD_svn=OFF
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
ecm_src_install
|
||||
rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
|
||||
}
|
||||
Binary file not shown.
@ -1,2 +1 @@
|
||||
DIST keysmith-23.04.2.tar.xz 161252 BLAKE2B b2bb39eafa86484b5f2d991a55129ee5bc6373e6c6c2393e1eb255b935319eea6ac5f2e898547219e3e1f4ce6a2d685922d2b41456ef1fec00f6d4461c099a90 SHA512 8086e9e383c178b5e0106085f9cf4adb52f15a4894e825fe36fed25e7dcb3de45fc099ef847f301f8be0ee5c6405abf55956cad777efca7a7305d7b85df067d5
|
||||
DIST keysmith-23.04.3.tar.xz 161996 BLAKE2B a160501a3fd29f83814611b0d738d6df487af0f98ffb7f9bb2c39b5ae67a3cc7af605f9d6c894d0e8ce351bd4d740b7247e1cf7541f4a1c1079110f384ce2de0 SHA512 a7ad96c91f5b50954aa185bdec81af8feafc1190105d28a3166b84442e5d58bd8a6dddcabd9d1f907b585f4082fe2dd16991b0c922bde087e1edfcc0b28027a1
|
||||
|
||||
@ -1,34 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
KDE_ORG_CATEGORY="utilities"
|
||||
ECM_TEST="true"
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="OTP client for Plasma Mobile and Desktop"
|
||||
HOMEPAGE="https://apps.kde.org/keysmith/"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="0"
|
||||
KEYWORDS="amd64 arm64 ~loong ~ppc64 x86"
|
||||
IUSE=""
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libsodium:=
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kirigami-${KFMIN}:5
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:5
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
>=dev-qt/qtconcurrent-${QTMIN}:5
|
||||
"
|
||||
Binary file not shown.
@ -1,3 +1,2 @@
|
||||
DIST ghostwriter-2.1.6.tar.gz 7757010 BLAKE2B a450093b1f072aeea7e6a6e27abbdb2c427387eb70b5ed2a5e49ea1f33fd9c4e4014742cc7905e644ab39838c488d9eddb79e0d3c87bde7ce6528cd810b02e15 SHA512 10ee557a07f468cc12391c2b5f77a6667aef76429b58bfdc03df32dd1cd8c44a61fe77da5318d5b23758ede40a5f8ab89cf4573a09708a6abc2d12ec5ceb71ad
|
||||
DIST ghostwriter-23.04.2.tar.xz 3072420 BLAKE2B 63f77711eccd1c7c9fffaed90942b7d52100a25802b886e1956330a00cfcc986b93726ce3b9523b6243e4252d99a2c1ec8c5fbe7e948528a603fd0bf1075198d SHA512 79123181cc3f4f0b8fade38f4daddad9fb019f433938d15f971c3457d7b6136b89c2ab5591d79874de930c39d008deeb2b5ba7d278a53da96b54bb9a0ae536be
|
||||
DIST ghostwriter-23.04.3.tar.xz 3074336 BLAKE2B 89314147c3222d0e83d26cedb81e6bf917e4f4e3d95650ba1d3096f06491343046dd5684d13014002a5249ec26af43cb050457c6f5d7c241b352a605b529b5af SHA512 d14e8c9928ec0638b98ca152d35ae88a7a4a582d4268e8f251252f080e4490b5c9433a814e6306acf7856c6a253f6e7aa9ed326328f90e0da8ef1214ef5a432c
|
||||
|
||||
@ -1,41 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
KDE_ORG_CATEGORY="office"
|
||||
ECM_HANDBOOK="optional"
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Cross-platform, aesthetic, distraction-free markdown editor"
|
||||
HOMEPAGE="https://ghostwriter.kde.org/"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="0"
|
||||
KEYWORDS="amd64 arm64 ~ppc64 ~x86"
|
||||
IUSE=""
|
||||
|
||||
RDEPEND="
|
||||
app-text/hunspell:=
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwebchannel-${QTMIN}:5
|
||||
>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:5
|
||||
>=kde-frameworks/sonnet-${KFMIN}:5
|
||||
virtual/opengl
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
>=dev-qt/qtconcurrent-${QTMIN}:5
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-qt/linguist-tools-${QTMIN}:5
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
DOCS=( CHANGELOG.md README.md )
|
||||
Binary file not shown.
@ -0,0 +1,45 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
# Packages which get releases together:
|
||||
# app-emacs/nxml-libvirt-schemas
|
||||
# dev-python/libvirt-python
|
||||
# dev-perl/Sys-Virt
|
||||
# app-emulation/libvirt
|
||||
# Please bump them together!
|
||||
|
||||
inherit elisp
|
||||
|
||||
MY_P="libvirt-${PV}"
|
||||
DESCRIPTION="Extension for nxml-mode with libvirt schemas"
|
||||
HOMEPAGE="https://www.libvirt.org/"
|
||||
SRC_URI="https://libvirt.org/sources/${MY_P}.tar.xz"
|
||||
S="${WORKDIR}/${MY_P%-rc*}/src/conf/schemas"
|
||||
|
||||
# This is the license of the package, but the schema files are
|
||||
# provided without license, maybe it's bad.
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
|
||||
# Yes this requires Java, but I'd rather not repackage this, if you
|
||||
# know something better in C, I'll be glad to use that.
|
||||
BDEPEND="app-text/trang"
|
||||
|
||||
SITEFILE="60${PN}-gentoo.el"
|
||||
|
||||
src_compile() {
|
||||
emake -f - <<'EOF'
|
||||
all: $(patsubst %.rng,%.rnc,$(wildcard *.rng))
|
||||
%.rnc: %.rng
|
||||
trang -I rng -O rnc $< $@
|
||||
EOF
|
||||
}
|
||||
|
||||
src_install() {
|
||||
insinto "${SITEETC}/${PN}"
|
||||
doins "${FILESDIR}"/schemas.xml *.rnc
|
||||
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
|
||||
}
|
||||
Binary file not shown.
@ -0,0 +1,363 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
# Packages which get releases together:
|
||||
# app-emacs/nxml-libvirt-schemas
|
||||
# dev-python/libvirt-python
|
||||
# dev-perl/Sys-Virt
|
||||
# app-emulation/libvirt
|
||||
# Please bump them together!
|
||||
|
||||
PYTHON_COMPAT=( python3_{9..11} )
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
|
||||
inherit meson linux-info python-any-r1 readme.gentoo-r1 tmpfiles verify-sig
|
||||
|
||||
if [[ ${PV} = *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
|
||||
EGIT_BRANCH="master"
|
||||
else
|
||||
SRC_URI="https://libvirt.org/sources/${P}.tar.xz
|
||||
verify-sig? ( https://libvirt.org/sources/${P}.tar.xz.asc )"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="C toolkit to manipulate virtual machines"
|
||||
HOMEPAGE="https://www.libvirt.org/ https://gitlab.com/libvirt/libvirt/"
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="0/${PV}"
|
||||
IUSE="
|
||||
apparmor audit bash-completion +caps dtrace firewalld fuse glusterfs
|
||||
iscsi iscsi-direct +libvirtd lvm libssh libssh2 lxc nfs nls numa openvz
|
||||
parted pcap policykit +qemu rbd sasl selinux test +udev
|
||||
virtualbox +virt-network wireshark-plugins xen zfs
|
||||
"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
REQUIRED_USE="
|
||||
firewalld? ( virt-network )
|
||||
libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
|
||||
lxc? ( caps libvirtd )
|
||||
openvz? ( libvirtd )
|
||||
qemu? ( libvirtd )
|
||||
virt-network? ( libvirtd )
|
||||
virtualbox? ( libvirtd )
|
||||
xen? ( libvirtd )"
|
||||
|
||||
BDEPEND="
|
||||
app-text/xhtml1
|
||||
dev-lang/perl
|
||||
dev-libs/libxslt
|
||||
dev-perl/XML-XPath
|
||||
dev-python/docutils
|
||||
virtual/pkgconfig
|
||||
net-libs/rpcsvc-proto
|
||||
bash-completion? ( >=app-shells/bash-completion-2.0 )
|
||||
verify-sig? ( sec-keys/openpgp-keys-libvirt )"
|
||||
|
||||
# gettext.sh command is used by the libvirt command wrappers, and it's
|
||||
# non-optional, so put it into RDEPEND.
|
||||
# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
|
||||
# package will use 3 by default. Since we don't have slot pinning in an API,
|
||||
# we must go with the most recent.
|
||||
RDEPEND="
|
||||
acct-user/qemu
|
||||
app-misc/scrub
|
||||
>=dev-libs/glib-2.56.0
|
||||
dev-libs/libgcrypt
|
||||
dev-libs/libnl:3
|
||||
>=dev-libs/libxml2-2.9.1
|
||||
>=net-analyzer/openbsd-netcat-1.105-r1
|
||||
>=net-libs/gnutls-3.2.0:=
|
||||
net-libs/libtirpc:=
|
||||
>=net-misc/curl-7.18.0
|
||||
sys-apps/dbus
|
||||
sys-apps/dmidecode
|
||||
sys-devel/gettext
|
||||
>=sys-libs/readline-7.0:=
|
||||
virtual/acl
|
||||
apparmor? ( sys-libs/libapparmor )
|
||||
audit? ( sys-process/audit )
|
||||
caps? ( sys-libs/libcap-ng )
|
||||
dtrace? ( dev-util/systemtap )
|
||||
firewalld? ( >=net-firewall/firewalld-0.6.3 )
|
||||
fuse? ( sys-fs/fuse:= )
|
||||
glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
|
||||
iscsi? ( >=sys-block/open-iscsi-1.18.0 )
|
||||
iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
|
||||
libssh? ( >=net-libs/libssh-0.8.1:= )
|
||||
libssh2? ( >=net-libs/libssh2-1.3 )
|
||||
lvm? ( >=sys-fs/lvm2-2.02.48-r2[lvm] )
|
||||
lxc? ( !sys-apps/systemd[cgroup-hybrid(-)] )
|
||||
nfs? ( net-fs/nfs-utils )
|
||||
numa? (
|
||||
>sys-process/numactl-2.0.2
|
||||
sys-process/numad
|
||||
)
|
||||
parted? (
|
||||
>=sys-block/parted-1.8[device-mapper]
|
||||
sys-fs/lvm2[lvm]
|
||||
)
|
||||
pcap? ( >=net-libs/libpcap-1.8.0 )
|
||||
policykit? (
|
||||
acct-group/libvirt
|
||||
>=sys-auth/polkit-0.9
|
||||
)
|
||||
qemu? (
|
||||
>=app-emulation/qemu-4.2
|
||||
app-crypt/swtpm
|
||||
>=dev-libs/yajl-2.0.3:=
|
||||
)
|
||||
rbd? ( sys-cluster/ceph )
|
||||
sasl? ( >=dev-libs/cyrus-sasl-2.1.26 )
|
||||
selinux? ( >=sys-libs/libselinux-2.0.85 )
|
||||
virt-network? (
|
||||
net-dns/dnsmasq[dhcp,ipv6(+),script]
|
||||
net-firewall/ebtables
|
||||
>=net-firewall/iptables-1.4.10[ipv6(+)]
|
||||
net-misc/radvd
|
||||
sys-apps/iproute2[-minimal]
|
||||
)
|
||||
wireshark-plugins? ( >=net-analyzer/wireshark-2.6.0:= )
|
||||
xen? (
|
||||
>=app-emulation/xen-4.9.0
|
||||
app-emulation/xen-tools:=
|
||||
)
|
||||
udev? (
|
||||
virtual/libudev:=
|
||||
>=x11-libs/libpciaccess-0.10.9
|
||||
)
|
||||
zfs? ( sys-fs/zfs )
|
||||
kernel_linux? ( sys-apps/util-linux )"
|
||||
DEPEND="
|
||||
${BDEPEND}
|
||||
${RDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
"
|
||||
# The 'circular' dependency on dev-python/libvirt-python is because of
|
||||
# virt-qemu-qmp-proxy.
|
||||
PDEPEND="
|
||||
qemu? ( dev-python/libvirt-python )
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-9.4.0-fix_paths_in_libvirt-guests_sh.patch
|
||||
"${FILESDIR}"/${PN}-9.4.0-do-not-use-sysconfig.patch
|
||||
"${FILESDIR}"/${PN}-9.6.0-fix-paths-for-apparmor.patch
|
||||
)
|
||||
|
||||
pkg_setup() {
|
||||
# Check kernel configuration:
|
||||
CONFIG_CHECK=""
|
||||
use fuse && CONFIG_CHECK+="
|
||||
~FUSE_FS"
|
||||
|
||||
use lvm && CONFIG_CHECK+="
|
||||
~BLK_DEV_DM
|
||||
~DM_MULTIPATH
|
||||
~DM_SNAPSHOT"
|
||||
|
||||
use lxc && CONFIG_CHECK+="
|
||||
~BLK_CGROUP
|
||||
~CGROUP_CPUACCT
|
||||
~CGROUP_DEVICE
|
||||
~CGROUP_FREEZER
|
||||
~CGROUP_NET_PRIO
|
||||
~CGROUP_PERF
|
||||
~CGROUPS
|
||||
~CGROUP_SCHED
|
||||
~CPUSETS
|
||||
~IPC_NS
|
||||
~MACVLAN
|
||||
~NAMESPACES
|
||||
~NET_CLS_CGROUP
|
||||
~NET_NS
|
||||
~PID_NS
|
||||
~POSIX_MQUEUE
|
||||
~SECURITYFS
|
||||
~USER_NS
|
||||
~UTS_NS
|
||||
~VETH
|
||||
~!GRKERNSEC_CHROOT_MOUNT
|
||||
~!GRKERNSEC_CHROOT_DOUBLE
|
||||
~!GRKERNSEC_CHROOT_PIVOT
|
||||
~!GRKERNSEC_CHROOT_CHMOD
|
||||
~!GRKERNSEC_CHROOT_CAPS"
|
||||
|
||||
kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
|
||||
~DEVPTS_MULTIPLE_INSTANCES"
|
||||
|
||||
use virt-network && CONFIG_CHECK+="
|
||||
~BRIDGE_EBT_MARK_T
|
||||
~BRIDGE_NF_EBTABLES
|
||||
~NETFILTER_ADVANCED
|
||||
~NETFILTER_XT_CONNMARK
|
||||
~NETFILTER_XT_MARK
|
||||
~NETFILTER_XT_TARGET_CHECKSUM
|
||||
~IP_NF_FILTER
|
||||
~IP_NF_MANGLE
|
||||
~IP_NF_NAT
|
||||
~IP6_NF_FILTER
|
||||
~IP6_NF_MANGLE
|
||||
~IP6_NF_NAT"
|
||||
|
||||
# This was renamed in kernel commit v5.2-rc1~133^2~174^2~6
|
||||
if use virt-network ; then
|
||||
if kernel_is -lt 5 2 ; then
|
||||
CONFIG_CHECK+="
|
||||
~IP_NF_TARGET_MASQUERADE"
|
||||
else
|
||||
CONFIG_CHECK+="
|
||||
~NETFILTER_XT_TARGET_MASQUERADE"
|
||||
fi
|
||||
fi
|
||||
|
||||
# Bandwidth Limiting Support
|
||||
use virt-network && CONFIG_CHECK+="
|
||||
~BRIDGE_EBT_T_NAT
|
||||
~IP_NF_TARGET_REJECT
|
||||
~NET_ACT_POLICE
|
||||
~NET_CLS_FW
|
||||
~NET_CLS_U32
|
||||
~NET_SCH_HTB
|
||||
~NET_SCH_INGRESS
|
||||
~NET_SCH_SFQ"
|
||||
|
||||
ERROR_USER_NS="Optional depending on LXC configuration."
|
||||
|
||||
if [[ -n ${CONFIG_CHECK} ]]; then
|
||||
linux-info_pkg_setup
|
||||
fi
|
||||
|
||||
python-any-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
touch "${S}/.mailmap" || die
|
||||
|
||||
default
|
||||
python_fix_shebang .
|
||||
|
||||
# Skip fragile tests which relies on pristine environment
|
||||
# (Breaks because of sandbox environment variables)
|
||||
# bug #802876
|
||||
sed -i -e "/commandtest/d" tests/meson.build || die
|
||||
|
||||
# Tweak the init script:
|
||||
cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
|
||||
sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
|
||||
-i "${S}/libvirtd.init" || die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_feature apparmor)
|
||||
$(meson_feature apparmor apparmor_profiles)
|
||||
$(meson_feature audit)
|
||||
$(meson_feature caps capng)
|
||||
$(meson_feature dtrace)
|
||||
$(meson_feature firewalld)
|
||||
$(meson_feature fuse)
|
||||
$(meson_feature glusterfs)
|
||||
$(meson_feature glusterfs storage_gluster)
|
||||
$(meson_feature iscsi storage_iscsi)
|
||||
$(meson_feature iscsi-direct storage_iscsi_direct)
|
||||
$(meson_feature libvirtd driver_libvirtd)
|
||||
$(meson_feature libssh)
|
||||
$(meson_feature libssh2)
|
||||
$(meson_feature lvm storage_lvm)
|
||||
$(meson_feature lvm storage_mpath)
|
||||
$(meson_feature lxc driver_lxc)
|
||||
$(meson_feature nls)
|
||||
$(meson_feature numa numactl)
|
||||
$(meson_feature numa numad)
|
||||
$(meson_feature openvz driver_openvz)
|
||||
$(meson_feature parted storage_disk)
|
||||
$(meson_feature pcap libpcap)
|
||||
$(meson_feature policykit polkit)
|
||||
$(meson_feature qemu driver_qemu)
|
||||
$(meson_feature qemu yajl)
|
||||
$(meson_feature rbd storage_rbd)
|
||||
$(meson_feature sasl)
|
||||
$(meson_feature selinux)
|
||||
$(meson_feature test tests)
|
||||
$(meson_feature udev)
|
||||
$(meson_feature virt-network driver_network)
|
||||
$(meson_feature virtualbox driver_vbox)
|
||||
$(meson_feature wireshark-plugins wireshark_dissector)
|
||||
$(meson_feature xen driver_libxl)
|
||||
$(meson_feature zfs storage_zfs)
|
||||
|
||||
-Dnetcf=disabled
|
||||
-Dsanlock=disabled
|
||||
-Dopenwsman=disabled
|
||||
|
||||
-Ddriver_esx=enabled
|
||||
-Dinit_script=systemd
|
||||
-Dqemu_user=$(usex caps qemu root)
|
||||
-Dqemu_group=$(usex caps qemu root)
|
||||
-Ddriver_remote=enabled
|
||||
-Dstorage_fs=enabled
|
||||
-Ddriver_vmware=enabled
|
||||
|
||||
--localstatedir="${EPREFIX}/var"
|
||||
-Dinitconfdir="${EPREFIX}/etc/systemd"
|
||||
-Drunstatedir="${EPREFIX}/run"
|
||||
-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
|
||||
)
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
export VIR_TEST_DEBUG=1
|
||||
# Don't run the syntax check tests, they're fragile and not relevant
|
||||
# to us downstream anyway.
|
||||
# We also crank up the timeout (as Fedora does) just to preempt failures
|
||||
# on slower arches.
|
||||
meson_src_test --no-suite syntax-check --timeout-multiplier 10
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
# Depending on configuration option, libvirt will create some bogus
|
||||
# directoreis. They are either not used, or libvirtd is able to create
|
||||
# them on demand, so let's remove them.
|
||||
#
|
||||
# Note, we are using -f here so that rm does not fail or warn if the
|
||||
# directory is nonexistent.
|
||||
rm -rf "${D}"/etc/sysconfig
|
||||
rm -rf "${D}"/var
|
||||
rm -rf "${D}"/run
|
||||
|
||||
use libvirtd || return 0
|
||||
# From here, only libvirtd-related instructions, be warned!
|
||||
|
||||
newtmpfiles "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
|
||||
|
||||
newinitd "${S}/libvirtd.init" libvirtd
|
||||
newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
|
||||
newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
|
||||
newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
|
||||
|
||||
newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
|
||||
newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
|
||||
|
||||
DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
|
||||
DISABLE_AUTOFORMATTING=true
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
|
||||
touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
|
||||
fi
|
||||
|
||||
use libvirtd || return 0
|
||||
# From here, only libvirtd-related instructions, be warned!
|
||||
tmpfiles_process libvirtd.conf
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
Binary file not shown.
@ -0,0 +1,14 @@
|
||||
Bug: https://bugs.gentoo.org/894514
|
||||
diff --git a/Makefile b/Makefile
|
||||
index 3819312..536c20b 100644
|
||||
--- a/Makefile
|
||||
+++ b/Makefile
|
||||
@@ -50,7 +50,7 @@ ifndef AFL_NO_X86
|
||||
|
||||
test_x86:
|
||||
@echo "[*] Checking for the ability to compile x86 code..."
|
||||
- @echo 'main() { __asm__("xorb %al, %al"); }' | $(CC) -w -x c - -o .test || ( echo; echo "Oops, looks like your compiler can't generate x86 code."; echo; echo "Don't panic! You can use the LLVM or QEMU mode, but see docs/INSTALL first."; echo "(To ignore this error, set AFL_NO_X86=1 and try again.)"; echo; exit 1 )
|
||||
+ @echo 'int main() { __asm__("xorb %al, %al"); }' | $(CC) -w -x c - -o .test || ( echo; echo "Oops, looks like your compiler can't generate x86 code."; echo; echo "Don't panic! You can use the LLVM or QEMU mode, but see docs/INSTALL first."; echo "(To ignore this error, set AFL_NO_X86=1 and try again.)"; echo; exit 1 )
|
||||
@rm -f .test
|
||||
@echo "[+] Everything seems to be working, ready to compile."
|
||||
|
||||
Binary file not shown.
@ -1,2 +1,3 @@
|
||||
DIST gnote-44.0.tar.xz 3330052 BLAKE2B 5b8a45de08419cdc8b22596fc4019ddd18edf7103dda5d51fe87153e624a3623a3b5af1e65ee15bc0afbefc13400ceddebc740fc34ff3675f4e0fa3a68ae87d5 SHA512 95299d811372f9c011e2966cd0fcb770830d691a85e390fbeb0500ff2db394301d0aeb478c622af1a8caf54d07cb15243c65e73809e02ae36407ef5006e636bb
|
||||
DIST gnote-44.1.tar.xz 3330072 BLAKE2B ff86fa34bdfff61eceb25abef1c73377f888082e70e539172849bf9425eada1c11000c1a75f69eb74fdbc2fc6d45ad3c58c843bf769279a026dd5298a07abc68 SHA512 89364d161d6ecc11822b89dec0353d0e20bc08d883573f324e4980ff2420361ddeb326213eb668fba4ce8de7d5d9668a1a058666ad2b81658ef94f8a65b87363
|
||||
DIST gnote-45.alpha.tar.xz 3320968 BLAKE2B d53d16f97cb737159c2888d0ffb3f4f6ec1f759a927ed4a50c2abb9ac0c9162e811cf976383c23a4f642b08370037d8d00197e6628528bff51ae1cc93803c07e SHA512 479dfe13cf1680bfdc65cb3ffc40c27bedf11519d38142a276e019062030e946d9a2b10badb0a230d1818aad665c1704e5f9bf8592fff11f9a0f0a6374fade1e
|
||||
|
||||
@ -0,0 +1,63 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit gnome2 meson readme.gentoo-r1
|
||||
|
||||
DESCRIPTION="Desktop note-taking application"
|
||||
HOMEPAGE="https://wiki.gnome.org/Apps/Gnote"
|
||||
|
||||
LICENSE="GPL-3+ FDL-1.1"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
|
||||
IUSE="test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
DEPEND="
|
||||
>=dev-libs/glib-2.74:2[dbus]
|
||||
>=dev-cpp/glibmm-2.74:2.68
|
||||
>=dev-cpp/gtkmm-4.0.0:4.0
|
||||
>=app-crypt/libsecret-0.8
|
||||
>=dev-libs/libxml2-2:2
|
||||
dev-libs/libxslt
|
||||
>=sys-apps/util-linux-2.16
|
||||
test? ( dev-libs/unittest++ )
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
gnome-base/gsettings-desktop-schemas
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/itstool
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Build system requires UnitTest++ >=1.5.1, but the .pc file doesn't
|
||||
# specify a version
|
||||
sed -i -e "/UnitTest++/ s/version: [^,]*,//" meson.build || die
|
||||
if ! use test; then
|
||||
sed -i -e "/unit_test_pp/ s/ = .*/ = disabler()/" meson.build || die
|
||||
fi
|
||||
|
||||
if has_version net-fs/wdfs; then
|
||||
DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
|
||||
synchronize notes."
|
||||
else
|
||||
DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
|
||||
If you want to use that functionality just emerge net-fs/wdfs.
|
||||
Gnote will automatically detect that you did and let you use it."
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
gnome2_pkg_postinst
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
Binary file not shown.
@ -1,2 +1 @@
|
||||
DIST kalendar-23.04.2.tar.xz 823744 BLAKE2B 7a6bb67a3884c99181bb84745808bab0ffd37c6d5abe8cd86b16d8109e84587cc7169007017461bfe8da6dcfcefd0279f9fdae1ab41f62caca12d3680bd5be38 SHA512 6688fe5f7fe296079bd181c892573edf07b35bf035c205a284fafcc06180b702144cce69be663606f4f54ecd9b23445acd19f31fbb72bad2a3135b0fea562191
|
||||
DIST kalendar-23.04.3.tar.xz 824472 BLAKE2B 0b60122066b0b1d63d631a397a6e417592dcce236fcf86dddc0a73b704a79fc4728225fb694559a15e46c0177b92ec5dc925c0564ca48c08652521194fd87cca SHA512 15bf7ce051ed56b4178e72a35d0aace00bd8650fac387bd4b63cc541aa92fd433eee2c5711663af4cd29606ddc69c838dbe58780a0e2e35f1fc4ef8be64dbb75
|
||||
|
||||
@ -1,60 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
KDE_ORG_CATEGORY="pim"
|
||||
ECM_TEST="forceoptional"
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Calendar application using Akonadi"
|
||||
HOMEPAGE="https://apps.kde.org/kalendar/"
|
||||
|
||||
LICENSE="|| ( GPL-2 GPL-3 ) CC0-1.0"
|
||||
SLOT="5"
|
||||
KEYWORDS="amd64 arm64 ~ppc64 ~x86"
|
||||
IUSE=""
|
||||
|
||||
# All of the tests involve interacting with akonadi right now (as of 22.04)
|
||||
RESTRICT="test"
|
||||
|
||||
DEPEND="
|
||||
app-crypt/gpgme:=[cxx]
|
||||
>=dev-libs/kirigami-addons-0.7.2:5
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=kde-apps/akonadi-${PVCUT}:5
|
||||
>=kde-apps/akonadi-calendar-${PVCUT}:5
|
||||
>=kde-apps/akonadi-contacts-${PVCUT}:5
|
||||
>=kde-apps/akonadi-mime-${PVCUT}:5
|
||||
>=kde-apps/calendarsupport-${PVCUT}:5
|
||||
>=kde-apps/eventviews-${PVCUT}:5
|
||||
>=kde-apps/mailcommon-${PVCUT}:5
|
||||
>=kde-apps/pimcommon-${PVCUT}:5
|
||||
>=kde-frameworks/kcalendarcore-${KFMIN}:5
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kcontacts-${KFMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:5
|
||||
>=kde-frameworks/kio-${KFMIN}:5
|
||||
>=kde-frameworks/kirigami-${KFMIN}:5
|
||||
>=kde-frameworks/kitemmodels-${KFMIN}:5
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:5
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:5
|
||||
"
|
||||
# qtlocation is needed at runtime only or fails to start
|
||||
RDEPEND="${DEPEND}
|
||||
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
|
||||
>=dev-qt/qtlocation-${QTMIN}:5
|
||||
>=dev-qt/qtwebengine-${QTMIN}:5
|
||||
>=kde-apps/kdepim-runtime-${PVCUT}:5
|
||||
>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
|
||||
"
|
||||
Binary file not shown.
@ -1,2 +1 @@
|
||||
DIST eix-0.36.6.tar.xz 640216 BLAKE2B 40f1d247f6a00ecc9e034f272e73346535724e1b0cf304ea990ae849414adb4490d181db1f781bf7825f18c12cee47e03921a3e43054631d2422e0a6c8a915b8 SHA512 4dbea2a0ac66b15061b491a8da15337894ef4ae18bfb2e77eaf74c6741a45487ca7378c80620341ccf4b335592c121ab55755f0562425a9dbf9a16a9c4aa3554
|
||||
DIST eix-0.36.7.tar.xz 639832 BLAKE2B 37202ae78378688ede95b410fe2e6325d63a9553dc082e4e09dc5bcd261f4e7bf49f349a92c286743c30a54cdc5bc1733fedebae33c37d601e6f5db1faf499e7 SHA512 5f5d059b502633be22c8a18fca410e2319061989bbc65b23592c87a9a109b93e615a5b5a7ca92a500999e3cc791e331b12e32a10700cc104040b1980f7f7a0f9
|
||||
|
||||
@ -1,104 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit autotools bash-completion-r1 tmpfiles
|
||||
|
||||
DESCRIPTION="Search and query ebuilds"
|
||||
HOMEPAGE="https://github.com/vaeth/eix/"
|
||||
SRC_URI="https://github.com/vaeth/eix/releases/download/v${PV}/${P}.tar.xz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
|
||||
IUSE="debug doc nls sqlite"
|
||||
|
||||
DEPEND="
|
||||
nls? ( virtual/libintl )
|
||||
sqlite? ( >=dev-db/sqlite-3:= )"
|
||||
RDEPEND="${DEPEND}
|
||||
>=app-shells/push-2.0-r1
|
||||
>=app-shells/quoter-3.0_p2-r1"
|
||||
BDEPEND="
|
||||
app-arch/xz-utils
|
||||
virtual/pkgconfig
|
||||
nls? ( sys-devel/gettext )"
|
||||
|
||||
pkg_setup() {
|
||||
# remove stale cache file to prevent collisions
|
||||
local old_cache=${EROOT}/var/cache/${PN}
|
||||
if [[ -f ${old_cache} ]]; then
|
||||
rm "${old_cache}" || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
sed -i -e "s:/:${EPREFIX}/:" tmpfiles.d/eix.conf || die
|
||||
|
||||
sed -e "/eixf_source=/s:push.sh:cat \"${EPREFIX}/usr/share/push/push.sh\":" \
|
||||
-e "/eixf_source=/s:quoter_pipe.sh:cat \"${EPREFIX}/usr/share/quoter/quoter_pipe.sh\":" \
|
||||
-i src/eix-functions.sh.in || die
|
||||
sed -e "s:'\$(bindir)/eix-functions.sh':cat \\\\\"${EPREFIX}/usr/share/eix/eix-functions\\\\\":" \
|
||||
-i src/Makefile.am || die
|
||||
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
$(use_enable debug paranoic-asserts)
|
||||
$(use_enable nls)
|
||||
$(use_with doc extra-doc)
|
||||
$(use_with sqlite)
|
||||
--without-protobuf
|
||||
|
||||
# default configuration
|
||||
$(use_with prefix always-accept-keywords)
|
||||
--with-dep-default
|
||||
--with-required-use-default
|
||||
|
||||
# paths
|
||||
--with-portage-rootpath="${ROOTPATH}"
|
||||
--with-eprefix-default="${EPREFIX}"
|
||||
|
||||
# build a single executable with symlinks
|
||||
--disable-separate-binaries
|
||||
--disable-separate-tools
|
||||
|
||||
# used purely to control/disrespect *FLAGS
|
||||
--disable-debugging
|
||||
--disable-new_dialect
|
||||
--disable-optimization
|
||||
--disable-strong-optimization
|
||||
--disable-security
|
||||
--disable-nopie-security
|
||||
--disable-strong-security
|
||||
)
|
||||
|
||||
econf "${myconf[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
dobashcomp bash/eix
|
||||
dotmpfiles tmpfiles.d/eix.conf
|
||||
|
||||
rm -r "${ED}"/usr/bin/eix-functions.sh || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
tmpfiles_process eix.conf
|
||||
|
||||
local obs=${EROOT}/var/cache/eix.previous
|
||||
if [[ -f ${obs} ]]; then
|
||||
ewarn "Found obsolete ${obs}, please remove it"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
if [[ ! -n ${REPLACED_BY_VERSION} ]]; then
|
||||
rm -rf "${EROOT}/var/cache/${PN}" || die
|
||||
fi
|
||||
}
|
||||
Binary file not shown.
Binary file not shown.
Binary file not shown.
Binary file not shown.
@ -1 +1,2 @@
|
||||
DIST cglm-0.8.9.tar.gz 631331 BLAKE2B 17f6f8d379aa81ee9327315b121cc7629fcc394fe032c1e1540e5153b2d3b0a2129f27eb46a8ae4323aa826b2bfff310b9039f78953d52d0bd994ba493fcdbd9 SHA512 ac0a042d61c60eac7d6616e5bc0f5c3e77b1a45f58f6732b34edc9a0d714046777e4b490200a3b54c6325ddad5b5faeb3648a299685f748f8b0618ce66a9a7f4
|
||||
DIST cglm-0.9.0.tar.gz 642861 BLAKE2B d02cb83abeeea793e5ab7b9473a9a26dcaf3e15209b555c34b6981e3becd6edbd94f0687126114a8917d9f4958575f2cf37a846b7fc54fd236d30198d1fe7aaf SHA512 23ad89df9cd80d69caf0fcf59d6acfbea710d9b6ae50634d4a32718d0214d1624df3bf8f874a76a93c3952e97f94ff48b65103035e87519bb9dbfce7fd2af427
|
||||
|
||||
@ -1,2 +1 @@
|
||||
DIST kopeninghours-23.04.2.tar.xz 71768 BLAKE2B 2ddcead9c00adbb210adea3affd44656b0fe7e0f0b496f78308291530a5fa56a06728b3977a861d4c605cfa1e592038772cb0f3b39b0e8d538aa87549b2ae9d5 SHA512 5378b23c12c9037512153630a643fe3ad0514e4e2113af59495ef1f323e46ba2fee7866f6f4f5325703ab5134c49948ebda46c491a1fbddc7fcb3e1bfd7593e3
|
||||
DIST kopeninghours-23.04.3.tar.xz 71808 BLAKE2B 734d938145fd386b6314f0e861a1b148e4a5dfac83f8b0263f8840e07f629c528f4945be16e3c6d8240b72b2be442a28071dc86982ee42b6faa60780ae15c0ee SHA512 6faddbf3da09fb4d3616abbc230c269f0ccb827f081ca3b2bf40874d7878efe69ea197ccf54f1b4db0e997eee11cca41891d64196b77062763d62e286ce4aa4c
|
||||
|
||||
@ -1,64 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_QTHELP="true"
|
||||
ECM_TEST="true"
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
PYTHON_COMPAT=( python3_{10..11} )
|
||||
inherit ecm gear.kde.org python-single-r1
|
||||
|
||||
DESCRIPTION="Library for parsing and evaluating OSM opening hours expressions"
|
||||
HOMEPAGE="https://api.kde.org/kopeninghours/html/index.html
|
||||
https://invent.kde.org/libraries/kopeninghours"
|
||||
|
||||
LICENSE="LGPL-2+"
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="python"
|
||||
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
DEPEND="
|
||||
>=dev-libs/kpublictransport-${PVCUT}:5
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=kde-frameworks/kholidays-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
sys-libs/zlib
|
||||
python? (
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
|
||||
')
|
||||
)
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
${PYTHON_DEPS}
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
"
|
||||
BDEPEND="
|
||||
sys-devel/bison
|
||||
sys-devel/flex
|
||||
"
|
||||
|
||||
PATCHES=( "${FILESDIR}"/${PN}-22.04.0-boostpython.patch )
|
||||
|
||||
pkg_setup() {
|
||||
ecm_pkg_setup
|
||||
python_setup
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
|
||||
$(cmake_use_find_package python Boost)
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
ecm_src_install
|
||||
python_optimize
|
||||
}
|
||||
@ -1,2 +1 @@
|
||||
DIST kosmindoormap-23.04.2.tar.xz 375472 BLAKE2B 5cfb5a5a5368d1e1b420faf30d73851495f425ecbc602e6d166875d0bfce4ce5fa2cd9026ce6bff249ddb48042943e0a15cc5acb886a332649ddab59e01191a5 SHA512 a5ce57ad4c1d92c31f47ff57d66fd70386901861e7b53bb80ed8a3827d124de6a045c3ead947c452e0a546a8b7bc27af614c471177ff80b9fa0cb3d56720efc7
|
||||
DIST kosmindoormap-23.04.3.tar.xz 375680 BLAKE2B 306336b33c7b03e67531f11163c579dab5b68614f4fd582eb14858a7c80e601e848aaf933c846a144d07e59c215b59f3a0021429f675a76750903144e02829d1 SHA512 1ad5acc7143842005cc02c146e90090d57d8fbafbac6a4401ab94ec966c709f66f7f832169982a808ab21911b16e6f837137c2fd9cf284c540ce03e6647c3405
|
||||
|
||||
@ -1,47 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_TEST="true"
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Data Model and Extraction System for Travel Reservation information"
|
||||
HOMEPAGE="https://invent.kde.org/libraries/kosmindoormap"
|
||||
|
||||
LICENSE="LGPL-2+"
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="+openinghours"
|
||||
|
||||
COMMON_DEPEND="
|
||||
>=dev-libs/kpublictransport-${PVCUT}:5
|
||||
dev-libs/protobuf:=
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtnetwork-${QTMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
sys-libs/zlib
|
||||
openinghours? ( >=dev-libs/kopeninghours-${PVCUT}:5 )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
test? ( >=dev-qt/qtwidgets-${QTMIN}:5 )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
"
|
||||
BDEPEND="
|
||||
sys-devel/bison
|
||||
sys-devel/flex
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_OsmTools=ON # we have no use for it
|
||||
$(cmake_use_find_package openinghours KOpeningHours)
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
@ -1,2 +1 @@
|
||||
DIST kpublictransport-23.04.2.tar.xz 535192 BLAKE2B 9a81c64284efc5ae02f9a2a8df080b49f56ec5553feb9e790b4d52b6ec22609a31b0a06c1dc7d05e0ca165adc3f8a4293eb0f49a542563cb31f2a04c68a7da83 SHA512 96ee9ddffa64a9d9a591866cde227f8901289ba41d06d1d7691ba20b9a4510ce6804e78150fd510b44622f4d0169c7ee62a5b6dd79e583065e3e4fac9033420b
|
||||
DIST kpublictransport-23.04.3.tar.xz 537716 BLAKE2B ee477dba15626a66cab15be59a1438c03d378df1e6686e5345211fa2139f0bec49ce3138f5e6cbdbd7ffb3ff6a58bd8ec1fcaa87c235af7aee7a23e926648953 SHA512 41597bf9e7c3366575a9a6698cace1f127f8c69094de906d0ab662cc563b0a440ae89c074909083d82c8d94e1cd5f2442470f45369663252b5cf6dd8f6ae7e47
|
||||
|
||||
@ -1,40 +0,0 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_QTHELP="true"
|
||||
ECM_TEST="true"
|
||||
KFMIN=5.106.0
|
||||
QTMIN=5.15.9
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Library for accessing public transport timetables and other information"
|
||||
HOMEPAGE="https://invent.kde.org/libraries/kpublictransport
|
||||
https://www.volkerkrause.eu/2019/03/02/kpublictransport-introduction.html"
|
||||
|
||||
LICENSE="LGPL-2+"
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="networkmanager"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/protobuf:=
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
sys-libs/zlib
|
||||
networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
test? ( >=dev-qt/qtwidgets-${QTMIN}:5 )
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_OsmTools=ON # we have no use for it
|
||||
$(cmake_use_find_package networkmanager KF5NetworkManagerQt)
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
Binary file not shown.
@ -0,0 +1,28 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Embed locations informations inside executable and libraries"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz -> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~ppc64 ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
RDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p ${PN} @install --display short -j $(makeopts_jobs) || die
|
||||
}
|
||||
@ -0,0 +1,39 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Helper library for gathering system configuration"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz -> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
BDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND="
|
||||
>=dev-ml/csexp-1.5:=[ocamlopt?]
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# This enables dune-configurator to use the vendored csexp module
|
||||
sed -i 's/stdune.csexp/dune-configurator.csexp/' \
|
||||
vendor/csexp/src/dune || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p "${PN}" @install -j $(makeopts_jobs) --profile release || die
|
||||
}
|
||||
@ -0,0 +1,36 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Private libraries of Dune"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz
|
||||
-> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
BDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND="
|
||||
>=dev-ml/csexp-1.5:=[ocamlopt?]
|
||||
dev-ml/pp:=[ocamlopt?]
|
||||
~dev-ml/dyn-${PV}:=[ocamlopt?]
|
||||
~dev-ml/stdune-${PV}:=[ocamlopt?]
|
||||
>=dev-lang/ocaml-4.08
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p "${PN}" @install -j $(makeopts_jobs) --profile release || die
|
||||
}
|
||||
@ -0,0 +1,31 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Embed locations informations inside executable and libraries"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz
|
||||
-> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
RDEPEND="
|
||||
~dev-ml/dune-private-libs-${PV}:=[ocamlopt=]
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p ${PN} @install -j $(makeopts_jobs) --display short || die
|
||||
}
|
||||
@ -0,0 +1,68 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit multiprocessing elisp-common
|
||||
|
||||
DESCRIPTION="A composable build system for OCaml"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="emacs"
|
||||
RESTRICT="strip test"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-lang/ocaml-4.08:=
|
||||
emacs? ( >=app-editors/emacs-23.1:* )
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
QA_FLAGS_IGNORED="usr/bin/dune"
|
||||
|
||||
BYTECOMPFLAGS="-L ${S}/editor-integration/emacs"
|
||||
SITEFILE="50${PN}-gentoo.el"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# This allows `dune --version` to output the correct version
|
||||
# instead of "n/a"
|
||||
sed -i "/^(name dune)/a (version ${PV})" dune-project || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
./configure \
|
||||
--libdir="$(ocamlc -where)" \
|
||||
--mandir=/usr/share/man \
|
||||
--docdir=/usr/doc \
|
||||
--etcdir=/etc \
|
||||
--datadir=/usr/share \
|
||||
--sbindir=/usr/sbin \
|
||||
--bindir=/usr/bin \
|
||||
|| die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
ocaml boot/bootstrap.ml -j $(makeopts_jobs) --verbose || die
|
||||
./_boot/dune.exe build @install -p "${PN}" --profile dune-bootstrap \
|
||||
-j $(makeopts_jobs) --display short || die
|
||||
|
||||
use emacs && elisp-compile editor-integration/emacs/*.el
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
|
||||
dodir /usr/share/doc
|
||||
mv "${ED}"/usr/doc/dune "${ED}"/usr/share/doc/${PF} || die
|
||||
rmdir "${ED}"/usr/doc || die
|
||||
|
||||
if use emacs ; then
|
||||
elisp-install ${PN} editor-integration/emacs/*.el{,c}
|
||||
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
|
||||
fi
|
||||
}
|
||||
@ -0,0 +1,31 @@
|
||||
# Copyright 2022-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Dynamic type"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz
|
||||
-> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
BDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND="~dev-ml/ordering-${PV}:=
|
||||
dev-ml/pp:="
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p "${PN}" @install -j $(makeopts_jobs) --profile release || die
|
||||
}
|
||||
@ -0,0 +1,30 @@
|
||||
# Copyright 2022-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Element ordering"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz
|
||||
-> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
BDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND=">=dev-lang/ocaml-4.08"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p "${PN}" @install -j $(makeopts_jobs) --profile release || die
|
||||
}
|
||||
@ -0,0 +1,36 @@
|
||||
# Copyright 2022-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dune multiprocessing
|
||||
|
||||
DESCRIPTION="Dune's unstable standard library"
|
||||
HOMEPAGE="https://github.com/ocaml/dune"
|
||||
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz
|
||||
-> dune-${PV}.tar.gz"
|
||||
S="${WORKDIR}/dune-${PV}"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="+ocamlopt"
|
||||
RESTRICT="test"
|
||||
|
||||
BDEPEND=">=dev-ml/dune-3.5"
|
||||
DEPEND="
|
||||
dev-ml/pp:=[ocamlopt?]
|
||||
~dev-ml/dyn-${PV}:=[ocamlopt?]
|
||||
~dev-ml/ordering-${PV}:=[ocamlopt?]
|
||||
>=dev-ml/csexp-1.5:=[ocamlopt?]
|
||||
!<dev-ml/dune-private-libs-3
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
src_configure() {
|
||||
:
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
dune build -p "${PN}" @install -j $(makeopts_jobs) --profile release || die
|
||||
}
|
||||
Some files were not shown because too many files have changed in this diff Show More
Loading…
Reference in new issue