gentoo-overlay/games-emulation/sameboy-jg/sameboy-jg-0.16.2.ebuild

# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

MY_PN=${PN%-*}
MY_P=${MY_PN}-${PV}
DESCRIPTION="Jolly Good Port of SameBoy"
HOMEPAGE="https://gitlab.com/jgemu/sameboy"
if [[ "${PV}" == *9999 ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://gitlab.com/jgemu/${MY_PN}.git"
else
	SRC_URI="https://gitlab.com/jgemu/${MY_PN}/-/archive/${PV}/${MY_P}.tar.bz2"
	S="${WORKDIR}/${MY_P}"
	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
fi

LICENSE="MIT"
SLOT="1"

DEPEND="
	media-libs/jg:1=
"
RDEPEND="
	${DEPEND}
	games-emulation/jgrf
"
BDEPEND="
	>=dev-util/rgbds-0.6.0
	virtual/pkgconfig
"

src_compile() {
	emake -C jollygood \
		CC="$(tc-getCC)" \
		CC_FOR_BUILD="$(tc-getBUILD_CC)" \
		PKG_CONFIG="$(tc-getPKG_CONFIG)"
}

src_install() {
	emake -C jollygood install \
		DESTDIR="${D}" \
		PREFIX="${EPREFIX}"/usr \
		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
}