gentoo-overlay/app-forensics/openscap/openscap-0.9.12.ebuild

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-0.9.12.ebuild,v 1.1 2013/09/19 15:31:32 hwoarang Exp $

EAPI=5

PYTHON_DEPEND="2"
PYTHON_COMPAT=( python{2_5,2_6,2_7} )

inherit bash-completion-r1 eutils multilib python-r1

DESCRIPTION="Framework which enables integration with the Security Content Automation Protocol (SCAP)"
HOMEPAGE="http://www.open-scap.org/"
SRC_URI="https://fedorahosted.org/releases/o/p/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion doc ldap nss perl python rpm selinux sce sql test"
RESTRICT="test"

RDEPEND="!nss? ( dev-libs/libgcrypt )
	nss? ( dev-libs/nss )
	ldap? ( net-nds/openldap )
	rpm? ( >=app-arch/rpm-4.9 )
	sql? ( dev-db/opendbx )
	dev-libs/libpcre
	dev-libs/libxml2
	dev-libs/libxslt
	net-misc/curl"
DEPEND="${RDEPEND}
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig )
	test? (
		app-arch/unzip
		dev-perl/XML-XPath
		net-misc/ipcalc
		sys-apps/grep )"

src_prepare() {
#	uncoment for debugging test
#	sed -i 's,set -e,&;set -x,'	tests/API/XCCDF/unittests/test_remediate_simple.sh || die
	sed -i 's,^    bash,    LC_ALL=C bash,'	tests/probes/process/test_probes_process.sh || die

	sed -i 's/uname -p/uname -m/' tests/probes/uname/test_probes_uname.xml.sh || die

	#probe runlevel for non-centos/redhat/fedora is not implemented
	sed -i 's,.*runlevel_test.*,echo "runlevel test bypassed",' tests/mitre/test_mitre.sh || die
	sed -i 's,probecheck "runlevel,probecheck "runlevellllll,' tests/probes/runlevel/test_probes_runlevel.sh || die

	#According to comment of theses tests, we must modify it. For the moment disable it
	sed -i 's,.*linux-def_inetlisteningservers_test,#&,' tests/mitre/test_mitre.sh || die
	sed -i 's,.*ind-def_environmentvariable_test,#&,' tests/mitre/test_mitre.sh || die

	# theses tests are hardcoded for checking hald process...,
	# but no good solution for the moment, disabling them with a fake echo
	# because encased in a if then
#	sed -i 's,ha.d,/sbin/udevd --daemon,g' tests/mitre/unix-def_process_test.xml || die
#	sed -i 's,ha.d,/sbin/udevd --daemon,g' tests/mitre/unix-def_process58_test.xml || die
	sed -i 's,.*process_test.*,echo "process test bypassed",' tests/mitre/test_mitre.sh || die
	sed -i 's,.*process58_test.*,echo "process58 test bypassed",' tests/mitre/test_mitre.sh || die

	#This test fail
	sed -i 's,.*generate report: xccdf,#&,' tests/API/XCCDF/unittests/all.sh ||	die

	if ! use rpm ; then
		sed -i 's,probe_rpminfo_req_deps_ok=yes,probe_rpminfo_req_deps_ok=no,' configure || die
		sed -i 's,probe_rpminfo_opt_deps_ok=yes,probe_rpminfo_opt_deps_ok=no,' configure || die
		sed -i 's,probe_rpmverify_req_deps_ok=yes,probe_rpmverify_req_deps_ok=no,' configure || die
		sed -i 's,probe_rpmverify_opt_deps_ok=yes,probe_rpmverify_opt_deps_ok=no,' configure || die
		sed -i 's,^probe_rpm.*_deps_missing=,&disabled_by_USE_flag,' configure || die
		sed -i 's,.*rpm.*,#&,' tests/mitre/test_mitre.sh || die
	fi
	if ! use selinux ; then
		einfo "Disabling SELinux probes"
		sed -i 's,.*selinux.*,	echo "SELinux test bypassed",' tests/mitre/test_mitre.sh || die
		#process58 need selinux
		sed -i 's,.*process58,#&,' tests/mitre/test_mitre.sh || die
	fi
	if ! use ldap; then
		einfo "Disabling LDAP probes"
		sed -i 's,ldap.h,ldapp.h,g' configure || die
	fi

	epatch_user
}

src_configure() {
	local myconf
	if use python ; then
		myconf+=" --enable-python"
	else
		myconf+=" --enable-python=no"
	fi
	if use perl ; then
		myconf+=" --enable-perl"
	fi
	if use nss ; then
		myconf+=" --with-crypto=nss3"
	else
		myconf+=" --with-crypto=gcrypt"
	fi
	if use sce ; then
		myconf+=" --enable-sce"
	else
		myconf+=" --enable-sce=no"
	fi
	econf ${myconf}
}

src_install() {
	emake install DESTDIR="${D}" || die
	find "${D}" -name '*.la' -delete || die
	if use doc ; then
		dohtml -r docs/html/* || die
		dodoc docs/examples/* || die
	fi
	if use bash-completion ; then
		dobashcomp "${D}"/etc/bash_completion.d/oscap
	fi
	rm -rf "${D}"/etc/bash_completion.d || die
}