gentoo-overlay/dev-python/scientificpython/scientificpython-2.9.2.ebuild

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/scientificpython/scientificpython-2.9.2.ebuild,v 1.3 2013/10/30 19:20:11 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1

MY_PN="ScientificPython"
MY_P="${MY_PN}-${PV}"
DOWNLOAD_NUMBER=4153

DESCRIPTION="Scientific Module for Python"
SRC_URI="http://sourcesup.cru.fr/frs/download.php/${DOWNLOAD_NUMBER}/${MY_P}.tar.gz"
HOMEPAGE="http://sourcesup.cru.fr/projects/scientific-py/"

LICENSE="CeCILL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc mpi test"

RDEPEND="
	dev-python/numpy[${PYTHON_USEDEP}]
	dev-python/pyro:3[${PYTHON_USEDEP}]
	sci-libs/netcdf
	mpi? ( virtual/mpi )"
DEPEND="${RDEPEND}
	dev-lang/python-exec:0[${PYTHON_USEDEP}]
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"

S="${WORKDIR}/${MY_P}"

# enforce python-exec:0 due to hackery in the ebuild, bug #484416
_PYTHON_WANT_PYTHON_EXEC2=0

PATCHES=( "${FILESDIR}"/${PN}-2.9-mpi.patch )
DOCS=( README README.MPI Doc/CHANGELOG Examples/demomodule.c Examples/netcdf_demo.py )

python_prepare_all() {
	use mpi && PATCHES+=( "${FILESDIR}"/${PN}-2.9.1-mpi-netcdf.patch )
	distutils-r1_python_prepare_all
}

python_compile() {
	distutils-r1_python_compile

	if use mpi; then
		cd Src/MPI
		building_of_mpipython() {
			${PYTHON} compile.py
			mv -f mpipython mpipython-${EPYTHON}
		}
		python_foreach_impl building_of_mpipython
	fi
}

python_test() {
	cd "${S}"/Tests || die
	python_foreach_impl nosetests
}

python_install_all() {
	use doc && HTML_DOCS=( Doc/Reference/. )
	distutils-r1_python_install_all

	if use mpi; then
		dobin Src/MPI/mpipython-${EPYTHON}
		dosym python-exec /usr/bin/mpipython
		insinto /usr/share/doc/${PF}
		doins Examples/mpi.py
	fi
}