gentoo-overlay/dev-ruby/fakefs/fakefs-0.4.0-r1.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/fakefs/fakefs-0.4.0-r1.ebuild,v 1.2 2012/05/20 18:28:15 graaff Exp $

EAPI=2

# jruby → Marshal/DeMarshal to clone directories fail; tests fail in
# release 0.2.1
USE_RUBY="ruby18 ree18 ruby19 jruby"

RUBY_FAKEGEM_TASK_TEST="test spec"

# requires sdoc
RUBY_FAKEGEM_TASK_DOC=""

RUBY_FAKEGEM_EXTRADOC="CONTRIBUTORS README.markdown"

inherit ruby-fakegem eutils

DESCRIPTION="A fake filesystem. Use it in your tests."
HOMEPAGE="http://github.com/defunkt/fakefs"

LICENSE="as-is" # truly
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""

ruby_add_bdepend "test? ( dev-ruby/rspec:2 )"

all_ruby_prepare() {
	# Remove bundler
	rm Gemfile || die

	epatch "${FILESDIR}/${P}-ruby193.patch"
	epatch "${FILESDIR}/${P}-ruby193-advise.patch"
	epatch "${FILESDIR}/${P}-ruby193-pathname.patch"
	epatch "${FILESDIR}/${P}-ruby193-ruby-pathname.patch"
}

each_ruby_prepare() {
	case ${RUBY} in
		*jruby)
			# Ignore failing tests: upstream is aware and doing the same
			# on Travis.
			rm test/fakefs_test.rb || die
			;;
		*)
			;;
	esac
}