You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
210 lines
6.8 KiB
210 lines
6.8 KiB
# Copyright 1999-2011 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Header: /var/cvsroot/gentoo-x86/dev-libs/openssl/openssl-1.0.0e-r1.ebuild,v 1.2 2011/12/07 16:03:05 vapier Exp $
|
|
|
|
EAPI="2"
|
|
|
|
inherit eutils flag-o-matic toolchain-funcs
|
|
|
|
REV="1.7"
|
|
DESCRIPTION="full-strength general purpose cryptography library (including SSL v2/v3 and TLS v1)"
|
|
HOMEPAGE="http://www.openssl.org/"
|
|
SRC_URI="mirror://openssl/source/${P}.tar.gz
|
|
http://cvs.pld-linux.org/cgi-bin/cvsweb.cgi/~checkout~/packages/${PN}/${PN}-c_rehash.sh?rev=${REV} -> ${PN}-c_rehash.sh.${REV}"
|
|
|
|
LICENSE="openssl"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
|
|
IUSE="bindist gmp kerberos rfc3779 sse2 static-libs test zlib"
|
|
|
|
# Have the sub-libs in RDEPEND with [static-libs] since, logically,
|
|
# our libssl.a depends on libz.a/etc... at runtime.
|
|
LIB_DEPEND="gmp? ( dev-libs/gmp[static-libs] )
|
|
zlib? ( sys-libs/zlib[static-libs] )
|
|
kerberos? ( app-crypt/mit-krb5 )"
|
|
RDEPEND="static-libs? ( ${LIB_DEPEND} )
|
|
!static-libs? ( ${LIB_DEPEND//\[static-libs]} )"
|
|
DEPEND="${RDEPEND}
|
|
sys-apps/diffutils
|
|
>=dev-lang/perl-5
|
|
test? ( sys-devel/bc )"
|
|
PDEPEND="app-misc/ca-certificates"
|
|
|
|
src_unpack() {
|
|
unpack ${P}.tar.gz
|
|
cp "${DISTDIR}"/${PN}-c_rehash.sh.${REV} "${WORKDIR}"/c_rehash || die
|
|
}
|
|
|
|
src_prepare() {
|
|
# Make sure we only ever touch Makefile.org and avoid patching a file
|
|
# that gets blown away anyways by the Configure script in src_configure
|
|
rm -f Makefile
|
|
|
|
epatch "${FILESDIR}"/${PN}-1.0.0a-ldflags.patch #327421
|
|
epatch "${FILESDIR}"/${PN}-1.0.0d-fbsd-amd64.patch #363089
|
|
epatch "${FILESDIR}"/${PN}-1.0.0d-windres.patch #373743
|
|
epatch "${FILESDIR}"/${PN}-1.0.0e-pkg-config.patch
|
|
epatch "${FILESDIR}"/${PN}-1.0.0e-parallel-build.patch
|
|
epatch "${FILESDIR}"/${PN}-1.0.0e-x32.patch
|
|
epatch_user #332661
|
|
|
|
# disable fips in the build
|
|
# make sure the man pages are suffixed #302165
|
|
# don't bother building man pages if they're disabled
|
|
sed -i \
|
|
-e '/DIRS/s: fips : :g' \
|
|
-e '/^MANSUFFIX/s:=.*:=ssl:' \
|
|
-e '/^MAKEDEPPROG/s:=.*:=$(CC):' \
|
|
-e $(has noman FEATURES \
|
|
&& echo '/^install:/s:install_docs::' \
|
|
|| echo '/^MANDIR=/s:=.*:=/usr/share/man:') \
|
|
Makefile.org \
|
|
|| die
|
|
# show the actual commands in the log
|
|
sed -i '/^SET_X/s:=.*:=set -x:' Makefile.shared
|
|
|
|
# allow openssl to be cross-compiled
|
|
cp "${FILESDIR}"/gentoo.config-1.0.0 gentoo.config || die
|
|
chmod a+rx gentoo.config
|
|
|
|
append-flags -fno-strict-aliasing
|
|
append-flags $(test-flags-CC -Wa,--noexecstack)
|
|
|
|
sed -i '1s,^:$,#!/usr/bin/perl,' Configure #141906
|
|
./config --test-sanity || die "I AM NOT SANE"
|
|
}
|
|
|
|
src_configure() {
|
|
unset APPS #197996
|
|
unset SCRIPTS #312551
|
|
unset CROSS_COMPILE #311473
|
|
|
|
tc-export CC AR RANLIB RC
|
|
|
|
# Clean out patent-or-otherwise-encumbered code
|
|
# Camellia: Royalty Free http://en.wikipedia.org/wiki/Camellia_(cipher)
|
|
# IDEA: 5,214,703 07/01/2012 http://en.wikipedia.org/wiki/International_Data_Encryption_Algorithm
|
|
# EC: ????????? ??/??/2015 http://en.wikipedia.org/wiki/Elliptic_Curve_Cryptography
|
|
# MDC2: Expired http://en.wikipedia.org/wiki/MDC-2
|
|
# RC5: 5,724,428 03/03/2015 http://en.wikipedia.org/wiki/RC5
|
|
|
|
use_ssl() { usex $1 "enable-${2:-$1}" "no-${2:-$1}" " ${*:3}" ; }
|
|
echoit() { echo "$@" ; "$@" ; }
|
|
|
|
local krb5=$(has_version app-crypt/mit-krb5 && echo "MIT" || echo "Heimdal")
|
|
|
|
local sslout=$(./gentoo.config)
|
|
einfo "Use configuration ${sslout:-(openssl knows best)}"
|
|
local config="Configure"
|
|
[[ -z ${sslout} ]] && config="config"
|
|
echoit \
|
|
./${config} \
|
|
${sslout} \
|
|
$(use sse2 || echo "no-sse2") \
|
|
enable-camellia \
|
|
$(use_ssl !bindist ec) \
|
|
$(use_ssl !bindist idea) \
|
|
enable-mdc2 \
|
|
$(use_ssl !bindist rc5) \
|
|
enable-tlsext \
|
|
$(use_ssl gmp gmp -lgmp) \
|
|
$(use_ssl kerberos krb5 --with-krb5-flavor=${krb5}) \
|
|
$(use_ssl rfc3779) \
|
|
$(use_ssl zlib) \
|
|
--prefix=/usr \
|
|
--openssldir=/etc/ssl \
|
|
--libdir=$(get_libdir) \
|
|
shared threads \
|
|
|| die
|
|
|
|
# Clean out hardcoded flags that openssl uses
|
|
local CFLAG=$(grep ^CFLAG= Makefile | LC_ALL=C sed \
|
|
-e 's:^CFLAG=::' \
|
|
-e 's:-fomit-frame-pointer ::g' \
|
|
-e 's:-O[0-9] ::g' \
|
|
-e 's:-march=[-a-z0-9]* ::g' \
|
|
-e 's:-mcpu=[-a-z0-9]* ::g' \
|
|
-e 's:-m[a-z0-9]* ::g' \
|
|
)
|
|
sed -i \
|
|
-e "/^CFLAG/s|=.*|=${CFLAG} ${CFLAGS}|" \
|
|
-e "/^SHARED_LDFLAGS=/s|$| ${LDFLAGS}|" \
|
|
Makefile || die
|
|
}
|
|
|
|
src_compile() {
|
|
# depend is needed to use $confopts; it also doesn't matter
|
|
# that it's -j1 as the code itself serializes subdirs
|
|
emake -j1 depend || die
|
|
emake all || die
|
|
# rehash is needed to prep the certs/ dir; do this
|
|
# separately to avoid parallel build issues.
|
|
emake rehash || die
|
|
}
|
|
|
|
src_test() {
|
|
emake -j1 test || die
|
|
}
|
|
|
|
src_install() {
|
|
emake INSTALL_PREFIX="${D}" install || die
|
|
dobin "${WORKDIR}"/c_rehash || die #333117
|
|
dodoc CHANGES* FAQ NEWS README doc/*.txt doc/c-indentation.el
|
|
dohtml -r doc/*
|
|
use rfc3779 && dodoc engines/ccgost/README.gost
|
|
|
|
# This is crappy in that the static archives are still built even
|
|
# when USE=static-libs. But this is due to a failing in the openssl
|
|
# build system: the static archives are built as PIC all the time.
|
|
# Only way around this would be to manually configure+compile openssl
|
|
# twice; once with shared lib support enabled and once without.
|
|
use static-libs || rm -f "${D}"/usr/lib*/lib*.a
|
|
|
|
# create the certs directory
|
|
dodir /etc/ssl/certs
|
|
cp -RP certs/* "${D}"/etc/ssl/certs/ || die
|
|
rm -r "${D}"/etc/ssl/certs/{demo,expired}
|
|
|
|
# Namespace openssl programs to prevent conflicts with other man pages
|
|
cd "${D}"/usr/share/man
|
|
local m d s
|
|
for m in $(find . -type f | xargs grep -L '#include') ; do
|
|
d=${m%/*} ; d=${d#./} ; m=${m##*/}
|
|
[[ ${m} == openssl.1* ]] && continue
|
|
[[ -n $(find -L ${d} -type l) ]] && die "erp, broken links already!"
|
|
mv ${d}/{,ssl-}${m}
|
|
# fix up references to renamed man pages
|
|
sed -i '/^[.]SH "SEE ALSO"/,/^[.]/s:\([^(, ]*(1)\):ssl-\1:g' ${d}/ssl-${m}
|
|
ln -s ssl-${m} ${d}/openssl-${m}
|
|
# locate any symlinks that point to this man page ... we assume
|
|
# that any broken links are due to the above renaming
|
|
for s in $(find -L ${d} -type l) ; do
|
|
s=${s##*/}
|
|
rm -f ${d}/${s}
|
|
ln -s ssl-${m} ${d}/ssl-${s}
|
|
ln -s ssl-${s} ${d}/openssl-${s}
|
|
done
|
|
done
|
|
[[ -n $(find -L ${d} -type l) ]] && die "broken manpage links found :("
|
|
|
|
dodir /etc/sandbox.d #254521
|
|
echo 'SANDBOX_PREDICT="/dev/crypto"' > "${D}"/etc/sandbox.d/10openssl
|
|
|
|
diropts -m0700
|
|
keepdir /etc/ssl/private
|
|
}
|
|
|
|
pkg_preinst() {
|
|
has_version ${CATEGORY}/${PN}:0.9.8 && return 0
|
|
preserve_old_lib /usr/$(get_libdir)/lib{crypto,ssl}.so.0.9.8
|
|
}
|
|
|
|
pkg_postinst() {
|
|
ebegin "Running 'c_rehash ${ROOT}etc/ssl/certs/' to rebuild hashes #333069"
|
|
c_rehash "${ROOT}etc/ssl/certs" >/dev/null
|
|
eend $?
|
|
|
|
has_version ${CATEGORY}/${PN}:0.9.8 && return 0
|
|
preserve_old_lib_notify /usr/$(get_libdir)/lib{crypto,ssl}.so.0.9.8
|
|
}
|