gentoo-overlay/dev-python/rootpy/rootpy-0.7.1.ebuild

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/rootpy/rootpy-0.7.1.ebuild,v 1.1 2013/08/12 17:32:01 bicatali Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_USE_WITH="readline"

inherit distutils-r1

DESCRIPTION="Pythonic layer on top of the ROOT framework's PyROOT bindings"
HOMEPAGE="http://rootpy.org"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples test"

RDEPEND="
	sci-physics/root[${PYTHON_USEDEP}]
	dev-python/matplotlib[${PYTHON_USEDEP}]
	dev-python/pytables[${PYTHON_USEDEP}]
	dev-python/root_numpy[${PYTHON_USEDEP}]
	dev-python/termcolor[${PYTHON_USEDEP}]"

DEPEND="
	sci-physics/root[${PYTHON_USEDEP}]
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"

# TOFIX: tests go in an infinite loop error
RESTRICT=test

python_test() {
	cd ${BUILD_DIR} || die
	nosetests -v || die "Testing failed with ${EPYTHON}"
}

python_install_all() {
	distutils-r1_python_install_all
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}