You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
208 lines
6.5 KiB
208 lines
6.5 KiB
# Copyright 1999-2017 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
|
|
DESCRIPTION="Fast, dense and secure container management"
|
|
HOMEPAGE="https://linuxcontainers.org/lxd/introduction/"
|
|
EGO_PN_PARENT="github.com/lxc"
|
|
EGO_PN="${EGO_PN_PARENT}/lxd"
|
|
|
|
# Maintained with https://github.com/hsoft/gentoo-ego-vendor-update
|
|
# The "# branch" comments are there for the script, they're important.
|
|
EGO_VENDOR=(
|
|
"github.com/dustinkirkland/golang-petname d3c2ba80e75eeef10c5cf2fc76d2c809637376b3"
|
|
"github.com/golang/protobuf 1643683e1b54a9e88ad26d98f81400c8c9d9f4f9"
|
|
"github.com/gorilla/mux 7625a85c14e615274a4ee4bc8654f72310a563e4"
|
|
"github.com/gorilla/websocket 71fa72d4842364bc5f74185f4161e0099ea3624a"
|
|
"github.com/gosexy/gettext 74466a0a0c4a62fea38f44aa161d4bbfbe79dd6b"
|
|
"github.com/jessevdk/go-flags f88afde2fa19a30cf50ba4b05b3d13bc6bae3079"
|
|
"github.com/mattn/go-colorable ad5389df28cdac544c99bd7b9161a0b5b6ca9d1b"
|
|
"github.com/mattn/go-runewidth 97311d9f7767e3d6f422ea06661bc2c7a19e8a5d"
|
|
"github.com/mattn/go-sqlite3 615c193e01d8d462eef7ee390171506f531a1c9a"
|
|
"github.com/olekukonko/tablewriter a7a4c189eb47ed33ce7b35f2880070a0c82a67d4"
|
|
"github.com/pborman/uuid e790cca94e6cc75c7064b1332e63811d4aae1a53"
|
|
"github.com/stretchr/testify 2aa2c176b9dab406a6970f6a55f513e8a8c8b18f"
|
|
"github.com/syndtr/gocapability db04d3cc01c8b54962a58ec7e491717d06cfcc16"
|
|
"github.com/go-stack/stack 817915b46b97fd7bb80e8ab6b69f01a53ac3eebf"
|
|
"github.com/mattn/go-isatty a5cdd64afdee435007ee3e9f6ed4684af949d568"
|
|
"github.com/juju/errors c7d06af17c68cd34c835053720b21f6549d9b0ee"
|
|
"golang.org/x/crypto 2509b142fb2b797aa7587dad548f113b2c0f20ce github.com/golang/crypto"
|
|
"golang.org/x/net c73622c77280266305273cb545f54516ced95b93 github.com/golang/net"
|
|
"golang.org/x/sync 8e0aa688b654ef28caa72506fa5ec8dba9fc7690 github.com/golang/sync"
|
|
"golang.org/x/text 6eab0e8f74e86c598ec3b6fad4888e0c11482d48 github.com/golang/text"
|
|
"golang.org/x/tools 9b61fcc4c548d69663d915801fc4b42a43b6cd9c github.com/golang/tools"
|
|
"golang.org/x/sys 661970f62f5897bc0cd5fdca7e087ba8a98a8fa1 github.com/golang/sys"
|
|
"gopkg.in/check.v1 20d25e2804050c1cd24a7eea1e7a6447dd0e74ec github.com/go-check/check" # branch v1
|
|
"gopkg.in/flosch/pongo2.v3 5e81b817a0c48c1c57cdf1a9056cf76bdee02ca9 github.com/flosch/pongo2" # branch v3
|
|
"gopkg.in/inconshreveable/log15.v2 0decfc6c20d9ca0ad143b0e89dcaa20f810b4fb3 github.com/inconshreveable/log15" # branch master
|
|
"gopkg.in/lxc/go-lxc.v2 74fb852c18ea4341f85e49bb6f33635946aabda7 github.com/lxc/go-lxc" # branch v2
|
|
"gopkg.in/tomb.v2 d5d1b5820637886def9eef33e03a27a9f166942c github.com/go-tomb/tomb" # branch v2
|
|
"gopkg.in/yaml.v2 eb3733d160e74a9c7e442f435eb3bea458e1d19f github.com/go-yaml/yaml" # branch v2
|
|
)
|
|
|
|
ARCHIVE_URI="https://${EGO_PN}/archive/${P}.tar.gz -> ${P}.tar.gz"
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
IUSE="+daemon +ipv6 +dnsmasq nls test"
|
|
|
|
inherit bash-completion-r1 linux-info systemd user golang-vcs-snapshot
|
|
|
|
SRC_URI="${ARCHIVE_URI}
|
|
${EGO_VENDOR_URI}"
|
|
|
|
DEPEND="
|
|
>=dev-lang/go-1.7.1
|
|
dev-libs/protobuf
|
|
nls? ( sys-devel/gettext )
|
|
test? (
|
|
app-misc/jq
|
|
dev-db/sqlite
|
|
net-misc/curl
|
|
sys-devel/gettext
|
|
)
|
|
"
|
|
|
|
RDEPEND="
|
|
daemon? (
|
|
app-arch/xz-utils
|
|
>=app-emulation/lxc-2.0.7[seccomp]
|
|
dnsmasq? (
|
|
net-dns/dnsmasq[dhcp,ipv6?]
|
|
)
|
|
net-misc/rsync[xattr]
|
|
sys-apps/iproute2[ipv6?]
|
|
sys-fs/squashfs-tools
|
|
virtual/acl
|
|
)
|
|
"
|
|
|
|
CONFIG_CHECK="
|
|
~BRIDGE
|
|
~DUMMY
|
|
~IP6_NF_NAT
|
|
~IP6_NF_TARGET_MASQUERADE
|
|
~IPV6
|
|
~IP_NF_NAT
|
|
~IP_NF_TARGET_MASQUERADE
|
|
~MACVLAN
|
|
~NETFILTER_XT_MATCH_COMMENT
|
|
~NET_IPGRE
|
|
~NET_IPGRE_DEMUX
|
|
~NET_IPIP
|
|
~NF_NAT_MASQUERADE_IPV4
|
|
~NF_NAT_MASQUERADE_IPV6
|
|
~VXLAN
|
|
"
|
|
|
|
ERROR_BRIDGE="BRIDGE: needed for network commands"
|
|
ERROR_DUMMY="DUMMY: needed for network commands"
|
|
ERROR_IP6_NF_NAT="IP6_NF_NAT: needed for network commands"
|
|
ERROR_IP6_NF_TARGET_MASQUERADE="IP6_NF_TARGET_MASQUERADE: needed for network commands"
|
|
ERROR_IPV6="IPV6: needed for network commands"
|
|
ERROR_IP_NF_NAT="IP_NF_NAT: needed for network commands"
|
|
ERROR_IP_NF_TARGET_MASQUERADE="IP_NF_TARGET_MASQUERADE: needed for network commands"
|
|
ERROR_MACVLAN="MACVLAN: needed for network commands"
|
|
ERROR_NETFILTER_XT_MATCH_COMMENT="NETFILTER_XT_MATCH_COMMENT: needed for network commands"
|
|
ERROR_NET_IPGRE="NET_IPGRE: needed for network commands"
|
|
ERROR_NET_IPGRE_DEMUX="NET_IPGRE_DEMUX: needed for network commands"
|
|
ERROR_NET_IPIP="NET_IPIP: needed for network commands"
|
|
ERROR_NF_NAT_MASQUERADE_IPV4="NF_NAT_MASQUERADE_IPV4: needed for network commands"
|
|
ERROR_NF_NAT_MASQUERADE_IPV6="NF_NAT_MASQUERADE_IPV6: needed for network commands"
|
|
ERROR_VXLAN="VXLAN: needed for network commands"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/${P}-dont-go-get.patch"
|
|
)
|
|
|
|
src_prepare() {
|
|
default_src_prepare
|
|
|
|
# Examples in go-lxc make our build fail.
|
|
rm -rf "${S}/src/${EGO_PN}/vendor/gopkg.in/lxc/go-lxc.v2/examples" || die
|
|
}
|
|
|
|
src_compile() {
|
|
export GOPATH="${S}"
|
|
|
|
cd "${S}/src/${EGO_PN}" || die "Failed to change to deep src dir"
|
|
|
|
tmpgoroot="${T}/goroot"
|
|
if use daemon; then
|
|
# Build binaries
|
|
emake
|
|
else
|
|
# build client tool
|
|
emake client
|
|
fi
|
|
|
|
use nls && emake build-mo
|
|
}
|
|
|
|
src_test() {
|
|
if use daemon; then
|
|
export GOPATH="${S}"
|
|
cd "${S}/src/${EGO_PN}" || die "Failed to change to deep src dir"
|
|
|
|
emake check
|
|
fi
|
|
}
|
|
|
|
src_install() {
|
|
dobin bin/lxc
|
|
if use daemon; then
|
|
dosbin bin/lxd
|
|
dobin bin/fuidshift
|
|
fi
|
|
|
|
cd "src/${EGO_PN}" || die "can't cd into ${S}/src/${EGO_PN}"
|
|
|
|
if use nls; then
|
|
domo po/*.mo
|
|
fi
|
|
|
|
if use daemon; then
|
|
newinitd "${FILESDIR}"/${PN}.initd lxd
|
|
newconfd "${FILESDIR}"/${PN}.confd lxd
|
|
|
|
systemd_newunit "${FILESDIR}"/${PN}.service ${PN}.service
|
|
fi
|
|
|
|
newbashcomp config/bash/lxd-client lxc
|
|
|
|
dodoc AUTHORS README.md doc/*
|
|
}
|
|
|
|
pkg_postinst() {
|
|
einfo
|
|
einfo "Consult https://wiki.gentoo.org/wiki/LXD for more information,"
|
|
einfo "including a Quick Start."
|
|
|
|
# The messaging below only applies to daemon installs
|
|
use daemon || return 0
|
|
|
|
# The control socket will be owned by (and writeable by) this group.
|
|
enewgroup lxd
|
|
|
|
# Ubuntu also defines an lxd user but it appears unused (the daemon
|
|
# must run as root)
|
|
|
|
einfo
|
|
einfo "Though not strictly required, some features are enabled at run-time"
|
|
einfo "when the relevant helper programs are detected:"
|
|
einfo "- sys-apps/apparmor"
|
|
einfo "- sys-fs/btrfs-progs"
|
|
einfo "- sys-fs/lvm2"
|
|
einfo "- sys-fs/lxcfs"
|
|
einfo "- sys-fs/zfs"
|
|
einfo "- sys-process/criu"
|
|
einfo
|
|
einfo "Since these features can't be disabled at build-time they are"
|
|
einfo "not USE-conditional."
|
|
einfo
|
|
einfo "Networks with bridge.mode=fan are unsupported due to requiring"
|
|
einfo "a patched kernel and iproute2."
|
|
}
|