74 lines
2 KiB
Bash
74 lines
2 KiB
Bash
# Copyright 1999-2013 Gentoo Foundation
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
# $Header: /var/cvsroot/gentoo-x86/sys-apps/man-db/man-db-2.6.4.ebuild,v 1.1 2013/06/24 22:07:11 radhermit Exp $
|
|
|
|
EAPI="4"
|
|
|
|
inherit eutils user
|
|
|
|
DESCRIPTION="a man replacement that utilizes berkdb instead of flat files"
|
|
HOMEPAGE="http://www.nongnu.org/man-db/"
|
|
SRC_URI="mirror://nongnu/${PN}/${P}.tar.xz"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~arm-linux ~x86-linux"
|
|
IUSE="berkdb +gdbm nls static-libs zlib"
|
|
|
|
RDEPEND="dev-libs/libpipeline
|
|
berkdb? ( sys-libs/db )
|
|
gdbm? ( sys-libs/gdbm )
|
|
!berkdb? ( !gdbm? ( sys-libs/gdbm ) )
|
|
sys-apps/groff
|
|
zlib? ( sys-libs/zlib )
|
|
!sys-apps/man"
|
|
DEPEND="${RDEPEND}
|
|
app-arch/xz-utils
|
|
virtual/pkgconfig
|
|
nls? (
|
|
app-text/po4a
|
|
sys-devel/gettext
|
|
)"
|
|
|
|
pkg_setup() {
|
|
# Create user now as Makefile in src_install does setuid/chown
|
|
enewgroup man 15
|
|
enewuser man 13 -1 /usr/share/man man
|
|
}
|
|
|
|
src_configure() {
|
|
export ac_cv_lib_z_gzopen=$(usex zlib)
|
|
econf \
|
|
--docdir='$(datarootdir)'/doc/${PF} \
|
|
--enable-setuid \
|
|
--with-sections="1 1p 8 2 3 3p 4 5 6 7 9 0p tcl n l p o 1x 2x 3x 4x 5x 6x 7x 8x" \
|
|
$(use_enable nls) \
|
|
$(use_enable static-libs static) \
|
|
--with-db=$(usex gdbm gdbm $(usex berkdb db gdbm))
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
dodoc docs/{HACKING,TODO}
|
|
prune_libtool_files
|
|
|
|
exeinto /etc/cron.daily
|
|
newexe "${FILESDIR}"/man-db.cron man-db #289884
|
|
|
|
keepdir /var/cache/man
|
|
fowners man:root /var/cache/man
|
|
fperms 2755 /var/cache/man
|
|
}
|
|
|
|
pkg_preinst() {
|
|
if [[ -f ${EROOT}var/cache/man/whatis ]] ; then
|
|
einfo "Cleaning ${EROOT}var/cache/man from sys-apps/man"
|
|
find "${EROOT}"var/cache/man -type f '!' '(' -name index.bt -o -name index.db ')' -delete
|
|
fi
|
|
if [[ ! -g ${EROOT}var/cache/man ]] ; then
|
|
einfo "Resetting permissions on ${EROOT}var/cache/man" #447944
|
|
mkdir -p "${EROOT}var/cache/man"
|
|
chown -R man:root "${EROOT}"var/cache/man
|
|
find "${EROOT}"var/cache/man -type d '!' -perm /g=s -exec chmod 2755 {} +
|
|
fi
|
|
}
|