gentoo-overlay/dev-perl/ExtUtils-CppGuess/ExtUtils-CppGuess-0.230.0.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DIST_AUTHOR=ETJ
DIST_VERSION=0.23
inherit perl-module toolchain-funcs

DESCRIPTION="Guess C++ compiler and flags"

SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="
	dev-perl/Capture-Tiny
	>=virtual/perl-ExtUtils-ParseXS-3.350.0
	virtual/perl-File-Spec
	virtual/perl-File-Temp
"
BDEPEND="${RDEPEND}
	virtual/perl-ExtUtils-MakeMaker
	test? (
		virtual/perl-File-Path
		virtual/perl-Data-Dumper
		>=virtual/perl-ExtUtils-CBuilder-0.280.231
		virtual/perl-ExtUtils-Manifest
		dev-perl/Module-Build
		>=virtual/perl-Test-Simple-0.880.0
	)
"

src_test() {
	# https://github.com/tsee/extutils-cppguess/issues/23
	tc-export CXX
	mkdir -p "${T}/bin" || die "Cant make dir ${T}/bin"
	einfo "CXX: ${CXX}"
	ln -vs "${EPREFIX}/usr/bin/${CXX}" "${T}/bin/g++" || die "Can't make symlink ${T}/bin/g++"
	PATH="${T}/bin:${PATH}" perl-module_src_test
}