gentoo-overlay/dev-dotnet/gtk-sharp/gtk-sharp-2.12.21.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

WANT_AUTOMAKE="1.11"
inherit autotools dotnet

DESCRIPTION="GTK bindings for mono"
HOMEPAGE="http://www.mono-project.com/GtkSharp"
SRC_URI="http://download.mono-project.com/sources/gtk-sharp212/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="amd64 x86"
IUSE="debug"

RESTRICT="test"

RDEPEND="
	>=dev-lang/mono-3.0
	x11-libs/pango
	>=dev-libs/glib-2.31
	dev-libs/atk
	x11-libs/gtk+:2
	gnome-base/libglade
	dev-perl/XML-LibXML
	!dev-dotnet/gtk-sharp-gapi
	!dev-dotnet/gtk-sharp-docs
	!dev-dotnet/gtk-dotnet-sharp
	!dev-dotnet/gdk-sharp
	!dev-dotnet/glib-sharp
	!dev-dotnet/glade-sharp
	!dev-dotnet/pango-sharp
	!dev-dotnet/atk-sharp
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}/${PN}-2.12.21-mono-ambiguous-range.patch"
)

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	econf \
		--disable-static \
		--disable-maintainer-mode \
		$(use_enable debug)
}

src_install() {
	default

	dotnet_multilib_comply
	sed -i "s/\\r//g" "${D}"/usr/bin/* || die "sed failed"
}