gentoo-overlay/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{8..10} pypy3 )
inherit distutils-r1

DESCRIPTION="Sphinx websupport extension"
HOMEPAGE="https://www.sphinx-doc.org
	https://github.com/sphinx-doc/sphinxcontrib-websupport"
# pypi tarball is missing templates
SRC_URI="https://github.com/sphinx-doc/sphinxcontrib-websupport/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"

RDEPEND="
	>=dev-python/six-1.5[${PYTHON_USEDEP}]
	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]"
# avoid circular dependency with sphinx
PDEPEND="
	>=dev-python/sphinx-1.5.3[${PYTHON_USEDEP}]"
BDEPEND="
	test? (
		${PDEPEND}
		>=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
		>=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
	)"

distutils_enable_tests pytest

src_prepare() {
	# breaks tests
	sed -i -e '/pkg_resources/d' \
		sphinxcontrib/websupport/__init__.py || die
	distutils-r1_src_prepare
}

python_install_all() {
	distutils-r1_python_install_all
	find "${ED}" -name '*.pth' -delete || die
}