You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
146 lines
4.2 KiB
146 lines
4.2 KiB
# Copyright 1999-2022 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
inherit autotools linux-info flag-o-matic toolchain-funcs systemd udev
|
|
|
|
DESCRIPTION="A performant, transport independent, multi-platform implementation of RFC3720"
|
|
HOMEPAGE="https://www.open-iscsi.com/"
|
|
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0/0.2"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
|
|
IUSE="debug infiniband +tcp rdma systemd"
|
|
REQUIRED_USE="infiniband? ( rdma ) || ( rdma tcp )"
|
|
|
|
DEPEND="
|
|
sys-apps/kmod
|
|
sys-block/open-isns:=
|
|
sys-kernel/linux-headers
|
|
infiniband? ( sys-cluster/rdma-core )
|
|
dev-libs/openssl:0=
|
|
systemd? ( sys-apps/systemd )
|
|
"
|
|
RDEPEND="${DEPEND}
|
|
sys-fs/lsscsi
|
|
sys-apps/util-linux"
|
|
BDEPEND="virtual/pkgconfig"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${PN}-2.1.7-fix_bitwise.patch
|
|
"${FILESDIR}"/${PN}-2.1.7-fix_sed.patch
|
|
"${FILESDIR}"/${PN}-2.1.7-no_werror.patch
|
|
)
|
|
|
|
pkg_setup() {
|
|
linux-info_pkg_setup
|
|
|
|
if kernel_is -lt 2 6 16; then
|
|
die "Sorry, your kernel must be 2.6.16-rc5 or newer!"
|
|
fi
|
|
|
|
# Needs to be done, as iscsid currently only starts, when having the iSCSI
|
|
# support loaded as module. Kernel builtin options don't work. See this for
|
|
# more information:
|
|
# https://groups.google.com/group/open-iscsi/browse_thread/thread/cc10498655b40507/fd6a4ba0c8e91966
|
|
# If there's a new release, check whether this is still valid!
|
|
TCP_MODULES="SCSI_ISCSI_ATTRS ISCSI_TCP"
|
|
RDMA_MODULES="INFINIBAND_ISER"
|
|
INFINIBAND_MODULES="INFINIBAND_IPOIB INIBAND_USER_MAD INFINIBAND_USER_ACCESS"
|
|
CONFIG_CHECK_MODULES="tcp? ( ${TCP_MODULES} ) rdma? ( ${RDMA_MODULES} ) infiniband? ( ${INFINIBAND_MODULES} )"
|
|
if linux_config_exists; then
|
|
if use tcp; then
|
|
for module in ${TCP_MODULES}; do
|
|
linux_chkconfig_module ${module} || ewarn "${module} needs to be built as module (builtin doesn't work)"
|
|
done
|
|
fi
|
|
if use infiniband; then
|
|
for module in ${INFINIBAND_MODULES}; do
|
|
linux_chkconfig_module ${module} || ewarn "${module} needs to be built as module (builtin doesn't work)"
|
|
done
|
|
fi
|
|
if use rdma; then
|
|
for module in ${RDMA_MODULES}; do
|
|
linux_chkconfig_module ${module} || ewarn "${module} needs to be built as module (builtin doesn't work)"$
|
|
done
|
|
fi
|
|
fi
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
pushd iscsiuio >/dev/null || die
|
|
eautoreconf
|
|
popd >/dev/null || die
|
|
}
|
|
|
|
src_configure() {
|
|
use debug && append-cppflags -DDEBUG_TCP -DDEBUG_SCSI
|
|
|
|
append-lfs-flags
|
|
}
|
|
|
|
src_compile() {
|
|
# Stuffing CPPFLAGS into CFLAGS isn't entirely correct, but the build
|
|
# is messed up already here, so it's not making it that much worse.
|
|
KSRC="${KV_DIR}" CFLAGS="" \
|
|
emake \
|
|
OPTFLAGS="${CFLAGS} ${CPPFLAGS} $(usex systemd '' -DNO_SYSTEMD)" \
|
|
AR="$(tc-getAR)" CC="$(tc-getCC)" \
|
|
$(usex systemd '' NO_SYSTEMD=1) \
|
|
user
|
|
}
|
|
|
|
src_install() {
|
|
# Force serial install to avoid race conditions
|
|
emake -j1 \
|
|
DESTDIR="${ED}" \
|
|
sbindir="/usr/sbin" \
|
|
SED="${EPREFIX}/bin/sed" \
|
|
systemddir="$(systemd_get_utildir)" \
|
|
install install_systemd
|
|
|
|
# Upstream make is not deterministic, per bug #601514
|
|
rm -f "${ED}"/etc/initiatorname.iscsi
|
|
|
|
# QA: install udev rule into right place
|
|
mkdir -p "${ED}"/lib/udev/rules.d
|
|
mv "${ED}"/etc/udev/rules.d/50-iscsi-firmware-login.rules \
|
|
"${ED}"/lib/udev/rules.d || die "mv failed"
|
|
|
|
# QA: let docompress compress man pages
|
|
gunzip -r "${ED}"/usr/share/man/man3/ || die "gunzip failed"
|
|
gunzip -r "${ED}"/usr/share/man/man8/ || die "gunzip failed"
|
|
|
|
dodoc README THANKS
|
|
|
|
docinto test/
|
|
dodoc $(find test -maxdepth 1 -type f ! -name ".*")
|
|
|
|
insinto /etc/iscsi
|
|
newins "${FILESDIR}"/initiatorname.iscsi initiatorname.iscsi.example
|
|
|
|
newconfd "${FILESDIR}"/iscsid-conf.d iscsid
|
|
newinitd "${FILESDIR}"/iscsid-init.d iscsid
|
|
|
|
keepdir /var/db/iscsi
|
|
fperms 700 /var/db/iscsi
|
|
fperms 600 /etc/iscsi/iscsid.conf
|
|
}
|
|
|
|
pkg_postinst() {
|
|
in='/etc/iscsi/initiatorname.iscsi'
|
|
if [[ ! -f "${EROOT}${in}" ]] && [[ -f "${EROOT}${in}.example" ]] ; then
|
|
{
|
|
cat "${EROOT}${in}.example"
|
|
echo "# InitiatorName generated by ${CATEGORY}/${PF} at $(date -uR)"
|
|
echo "InitiatorName=$(${ROOT}/usr/sbin/iscsi-iname)"
|
|
} >> "${EROOT}${in}.tmp" && mv -f "${EROOT}${in}.tmp" "${EROOT}${in}"
|
|
fi
|
|
|
|
udev_reload
|
|
}
|