gentoo-overlay/dev-php/symfony-finder/symfony-finder-3.2.6.ebuild

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

DESCRIPTION=" Symfony Finder Component"
HOMEPAGE="https://github.com/symfony/finder"
SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> symfony-finder-${PV}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
# 20170204-The test suite is broken in 3.1.10 on php-5.x
RESTRICT="test"

RDEPEND="
	dev-lang/php:*
	dev-php/fedora-autoloader"
DEPEND="
	test? (
		${RDEPEND}
		dev-php/phpunit )"

S="${WORKDIR}/finder-${PV}"

src_prepare() {
	default
	if use test; then
		cp "${FILESDIR}"/autoload.php "${S}"/autoload-test.php || die
	fi
}

src_install() {
	insinto "/usr/share/php/Symfony/Component/Finder"
	doins -r Comparator Exception Iterator Finder.php \
	Glob.php LICENSE SplFileInfo.php "${FILESDIR}"/autoload.php
	dodoc README.md
}

src_test() {
	phpunit --bootstrap "${S}"/autoload-test.php || die "test suite failed"
}