gentoo-overlay/dev-python/loguru/loguru-0.2.6_pre20190412.ebuild

# Copyright 2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{5,6,7} )

inherit distutils-r1

EGIT_COMMIT="6571879c37904e3a18567e694d70651c6886b860"

DESCRIPTION="Python logging made (stupidly) simple"
HOMEPAGE="https://github.com/Delgan/loguru"
SRC_URI="https://github.com/Delgan/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

DEPEND="
	>=dev-python/ansimarkup-1.4.0[${PYTHON_USEDEP}]
	>=dev-python/colorama-0.3.4[${PYTHON_USEDEP}]
	doc? (
		dev-python/sphinx[${PYTHON_USEDEP}]
		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
	)
	test? (
		>=dev-python/isort-4.3.4[${PYTHON_USEDEP}]
		>=dev-python/pytest-3.9.0[${PYTHON_USEDEP}]
	)
"
RDEPEND="${DEPEND}"
BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"

S="${WORKDIR}/${PN}-${EGIT_COMMIT}"

python_compile_all() {
	use doc && esetup.py build_sphinx
}

python_install_all() {
	use doc && HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
	distutils-r1_python_install_all
}

python_test() {
	pytest -v || die "Tests failed with ${EPYTHON}"
}