gentoo-overlay/dev-php/pecl-event/pecl-event-3.0.2_p1.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

PHP_EXT_NAME="event"
PHP_EXT_INI="yes"
PHP_EXT_ZENDEXT="no"
DOCS=( README.md )

USE_PHP="php7-3 php7-4 php8-0"
#Unique to this release
MY_P="${PN/pecl-/}-${PV/_p/r}"
PHP_EXT_PECL_FILENAME="${MY_P}.tgz"

inherit php-ext-pecl-r3

KEYWORDS="~amd64 ~ia64 ~x86"
LICENSE="PHP-3.01"

DESCRIPTION="PHP wrapper for libevent2"
SLOT="0"

DEPEND="
	>=dev-libs/libevent-2.0.2
	ssl? ( dev-libs/openssl:0= )
	php_targets_php7-3? ( dev-lang/php:7.3[sockets(-)?] )
	php_targets_php7-4? ( dev-lang/php:7.4[sockets(-)?] )
	php_targets_php8-0? ( dev-lang/php:8.0[sockets(-)?] )"

RDEPEND="
	${DEPEND}
	!dev-php/pecl-libevent"

IUSE="debug examples +extra +sockets +ssl threads"
#Unique to this release
S="${WORKDIR}/${MY_P}"
PHP_EXT_S="${S}"

src_configure() {
	local PHP_EXT_ECONF_ARGS=(
		--with-event-core
		$(use_enable debug event-debug)
		$(use_with extra event-extra)
		$(use_with ssl event-openssl)
		$(use_with threads event-pthreads)
		$(use_enable sockets event-sockets)
	)
	php-ext-source-r3_src_configure
}

src_test() {
	local slot
	for slot in $(php_get_slots); do
		php_init_slot_env "${slot}"
		SKIP_ONLINE_TESTS="yes" NO_INTERACTION="yes" emake test
	done
}