gentoo-overlay/games-simulation/lincity/lincity-1.13.1-r1.ebuild

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit eutils flag-o-matic

DESCRIPTION="city/country simulation game for X and Linux SVGALib"
HOMEPAGE="http://lincity.sourceforge.net/"
SRC_URI="mirror://sourceforge/lincity/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

# dep fix (bug #82318)
RDEPEND="media-libs/libpng:0
	x11-libs/libSM
	x11-libs/libXext
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

PATCHES=(
	"${FILESDIR}"/${P}-build.patch
	"${FILESDIR}"/${P}-gcc-10.patch
)

src_prepare() {
	default

	append-cflags -std=gnu89 # build with gcc5 (bug #570574)
}

src_configure() {
	econf \
		$(use_enable nls) \
		--with-gzip \
		--with-x
}

src_compile() {
	# build system logic is severely broken
	emake
	emake X_PROGS
}

src_install() {
	default
	dodoc Acknowledgements CHANGES README* TODO
	make_desktop_entry xlincity Lincity
	dobin xlincity
}