gentoo-overlay/net-libs/libesmtp/libesmtp-1.0.6-r3.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools

DESCRIPTION="lib that implements the client side of the SMTP protocol"
HOMEPAGE="http://brianstafford.info/libesmtp/"
SRC_URI="http://brianstafford.info/${PN}/${P}.tar.bz2"

LICENSE="LGPL-2.1 GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
IUSE="debug ntlm ssl static-libs threads"

RDEPEND="
	ssl? (
		dev-libs/openssl:0=
	)"
DEPEND="${RDEPEND}"

DOCS=( AUTHORS ChangeLog NEWS Notes README TODO )

PATCHES=(
	"${FILESDIR}/${P}-openssl-1.1-api-compatibility.patch"
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf \
		--enable-all \
		$(use_enable static-libs static) \
		$(use_enable ntlm) \
		$(use_enable threads pthreads) \
		$(use_enable debug) \
		$(use_with ssl openssl)
}

src_install() {
	default

	docinto xml
	dodoc doc/api.xml
}