You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 

172 rivejä
7.3 KiB

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. # NOTE: The comments in this file are for instruction and documentation.
  4. # They're not meant to appear with your final, production ebuild. Please
  5. # remember to remove them before submitting or committing your ebuild. That
  6. # doesn't mean you can't add your own comments though.
  7. # The EAPI variable tells the ebuild format in use.
  8. # It is suggested that you use the latest EAPI approved by the Council.
  9. # The PMS contains specifications for all EAPIs. Eclasses will test for this
  10. # variable if they need to use features that are not universal in all EAPIs.
  11. # If an eclass doesn't support latest EAPI, use the previous EAPI instead.
  12. EAPI=7
  13. # inherit lists eclasses to inherit functions from. For example, an ebuild
  14. # that needs the eautoreconf function from autotools.eclass won't work
  15. # without the following line:
  16. #inherit autotools
  17. #
  18. # Eclasses tend to list descriptions of how to use their functions properly.
  19. # Take a look at the eclass/ directory for more examples.
  20. # Short one-line description of this package.
  21. DESCRIPTION="This is a sample skeleton ebuild file"
  22. # Homepage, not used by Portage directly but handy for developer reference
  23. HOMEPAGE="https://foo.example.org/"
  24. # Point to any required sources; these will be automatically downloaded by
  25. # Portage.
  26. SRC_URI="ftp://foo.example.org/${P}.tar.gz"
  27. # Source directory; the dir where the sources can be found (automatically
  28. # unpacked) inside ${WORKDIR}. The default value for S is ${WORKDIR}/${P}
  29. # If you don't need to change it, leave the S= line out of the ebuild
  30. # to keep it tidy.
  31. #S="${WORKDIR}/${P}"
  32. # License of the package. This must match the name of file(s) in the
  33. # licenses/ directory. For complex license combination see the developer
  34. # docs on gentoo.org for details.
  35. LICENSE=""
  36. # The SLOT variable is used to tell Portage if it's OK to keep multiple
  37. # versions of the same package installed at the same time. For example,
  38. # if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
  39. # with 1.2.2), it would be optimal to instruct Portage to not remove
  40. # libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2. To do this,
  41. # we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
  42. # emerge clean understands SLOTs, and will keep the most recent version
  43. # of each SLOT and remove everything else.
  44. # Note that normal applications should use SLOT="0" if possible, since
  45. # there should only be exactly one version installed at a time.
  46. # Do not use SLOT="", because the SLOT variable must not be empty.
  47. SLOT="0"
  48. # Using KEYWORDS, we can record masking information *inside* an ebuild
  49. # instead of relying on an external package.mask file. Right now, you
  50. # should set the KEYWORDS variable for every ebuild so that it contains
  51. # the names of all the architectures with which the ebuild works.
  52. # All of the official architectures can be found in the arch.list file
  53. # which is in the profiles/ directory. Usually you should just set this
  54. # to "~amd64". The ~ in front of the architecture indicates that the
  55. # package is new and should be considered unstable until testing proves
  56. # its stability. So, if you've confirmed that your ebuild works on
  57. # amd64 and ppc, you'd specify:
  58. # KEYWORDS="~amd64 ~ppc"
  59. # Once packages go stable, the ~ prefix is removed.
  60. # For binary packages, use -* and then list the archs the bin package
  61. # exists for. If the package was for an x86 binary package, then
  62. # KEYWORDS would be set like this: KEYWORDS="-* x86"
  63. # Do not use KEYWORDS="*"; this is not valid in an ebuild context.
  64. KEYWORDS="~amd64"
  65. # Comprehensive list of any and all USE flags leveraged in the ebuild,
  66. # with some exceptions, e.g., ARCH specific flags like "amd64" or "ppc".
  67. # Not needed if the ebuild doesn't use any USE flags.
  68. IUSE="gnome X"
  69. # A space delimited list of portage features to restrict. man 5 ebuild
  70. # for details. Usually not needed.
  71. #RESTRICT="strip"
  72. # Run-time dependencies. Must be defined to whatever this depends on to run.
  73. # Example:
  74. # ssl? ( >=dev-libs/openssl-1.0.2q:0= )
  75. # >=dev-lang/perl-5.24.3-r1
  76. # It is advisable to use the >= syntax show above, to reflect what you
  77. # had installed on your system when you tested the package. Then
  78. # other users hopefully won't be caught without the right version of
  79. # a dependency.
  80. #RDEPEND=""
  81. # Build-time dependencies that need to be binary compatible with the system
  82. # being built (CHOST). These include libraries that we link against.
  83. # The below is valid if the same run-time depends are required to compile.
  84. #DEPEND="${RDEPEND}"
  85. # Build-time dependencies that are executed during the emerge process, and
  86. # only need to be present in the native build system (CBUILD). Example:
  87. #BDEPEND="virtual/pkgconfig"
  88. # The following src_configure function is implemented as default by portage, so
  89. # you only need to call it if you need a different behaviour.
  90. #src_configure() {
  91. # Most open-source packages use GNU autoconf for configuration.
  92. # The default, quickest (and preferred) way of running configure is:
  93. #econf
  94. #
  95. # You could use something similar to the following lines to
  96. # configure your package before compilation. The "|| die" portion
  97. # at the end will stop the build process if the command fails.
  98. # You should use this at the end of critical commands in the build
  99. # process. (Hint: Most commands are critical, that is, the build
  100. # process should abort if they aren't successful.)
  101. #./configure \
  102. # --host=${CHOST} \
  103. # --prefix=/usr \
  104. # --infodir=/usr/share/info \
  105. # --mandir=/usr/share/man || die
  106. # Note the use of --infodir and --mandir, above. This is to make
  107. # this package FHS 2.2-compliant. For more information, see
  108. # https://wiki.linuxfoundation.org/lsb/fhs
  109. #}
  110. # The following src_compile function is implemented as default by portage, so
  111. # you only need to call it, if you need different behaviour.
  112. #src_compile() {
  113. # emake is a script that calls the standard GNU make with parallel
  114. # building options for speedier builds (especially on SMP systems).
  115. # Try emake first. It might not work for some packages, because
  116. # some makefiles have bugs related to parallelism, in these cases,
  117. # use emake -j1 to limit make to a single process. The -j1 is a
  118. # visual clue to others that the makefiles have bugs that have been
  119. # worked around.
  120. #emake
  121. #}
  122. # The following src_install function is implemented as default by portage, so
  123. # you only need to call it, if you need different behaviour.
  124. #src_install() {
  125. # You must *personally verify* that this trick doesn't install
  126. # anything outside of DESTDIR; do this by reading and
  127. # understanding the install part of the Makefiles.
  128. # This is the preferred way to install.
  129. #emake DESTDIR="${D}" install
  130. # When you hit a failure with emake, do not just use make. It is
  131. # better to fix the Makefiles to allow proper parallelization.
  132. # If you fail with that, use "emake -j1", it's still better than make.
  133. # For Makefiles that don't make proper use of DESTDIR, setting
  134. # prefix is often an alternative. However if you do this, then
  135. # you also need to specify mandir and infodir, since they were
  136. # passed to ./configure as absolute paths (overriding the prefix
  137. # setting).
  138. #emake \
  139. # prefix="${D}"/usr \
  140. # mandir="${D}"/usr/share/man \
  141. # infodir="${D}"/usr/share/info \
  142. # libdir="${D}"/usr/$(get_libdir) \
  143. # install
  144. # Again, verify the Makefiles! We don't want anything falling
  145. # outside of ${D}.
  146. #}