gentoo-overlay/net-misc/yt-dlp/yt-dlp-2021.12.27.ebuild

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{8..10} )
inherit bash-completion-r1 distutils-r1 optfeature

DESCRIPTION="youtube-dl fork with additional features and fixes"
HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"

LICENSE="Unlicense"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv x86"

RDEPEND="
	dev-python/pycryptodome[${PYTHON_USEDEP}]
	!net-misc/youtube-dl"

distutils_enable_tests pytest

python_prepare_all() {
	distutils-r1_python_prepare_all

	# adjust requires for pycryptodome and optional dependencies (bug #828466)
	sed -ri setup.py \
		-e "s/'(pycryptodome)x'/'\1'/" \
		-e "s/'(mutagen|websockets)',?//g" || die
}

python_test() {
	epytest -m 'not download' -p no:markdown
}

python_install() {
	distutils-r1_python_install

	local sitedir=$(python_get_sitedir)
	dosym yt_dlp "${sitedir#${EPREFIX}}"/youtube_dl
}

python_install_all() {
	dodoc README.md Changelog.md supportedsites.md
	doman yt-dlp.1

	dobashcomp completions/bash/yt-dlp

	insinto /usr/share/fish/vendor_completions.d
	doins completions/fish/yt-dlp.fish

	insinto /usr/share/zsh/site-functions
	doins completions/zsh/_yt-dlp

	rm -r "${ED}"/usr/share/doc/yt_dlp || die

	newbin - youtube-dl <<-EOF
		#!/usr/bin/env sh
		exec yt-dlp --compat-options youtube-dl "\${@}"
	EOF
}

pkg_postinst() {
	optfeature "various features (merging tracks, streamed content)" media-video/ffmpeg
	has_version media-video/atomicparsley || # allow fallback but don't advertise
		optfeature "embedding metadata thumbnails in MP4/M4A files" media-libs/mutagen

	if [[ ! ${REPLACING_VERSIONS} ]] ||
		ver_test ${REPLACING_VERSIONS} -lt 2021.10.22-r2; then
		elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
		elog 'as "youtube-dl". This is strictly for compatibility and it is'
		elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
	fi
}