openshot 3.1.1 with deps

1 year ago · 0c067ebbaf
parent b5cc5ea0c0
commit 0c067ebbaf
7 changed files with 201 additions and 0 deletions
--- a/media-libs/libopenshot-audio/Manifest
+++ b/media-libs/libopenshot-audio/Manifest
@ -1 +1,2 @@
 DIST libopenshot-audio-0.3.0.tar.gz 1772242 BLAKE2B a5cc1eba31ebc9750d69046d0a8963a5b4af5615bf57ca3ecb9989fc0c67ffd525b19162958aaab14d51d0d29ce9643da86f8bd1afd8de8e0483bfe11663c893 SHA512 75f4f4170f8e4f442a31834e65b9ab56bfb2e034d81e0015add5d79c9ccaa3dd2806ae78b1ca97fab20eefa4c37990609755d0c07c306ca19f9cdca3884f0163
+DIST libopenshot-audio-0.3.2.tar.gz 1772366 BLAKE2B 3b0157f88d28cfc4d147eea86b621c836aee48510d76db6ec6e88773cc1ee677dc635ea9a84e04754be463a1cd4bc80e6830c7cbf31a968ed0900732b007ff7c SHA512 f10a709c748f37cd74a49e760eded67d14a24d4932401d62d616854c105f2d5a09b2a91f31190123d3f82f792f08976fedd9a4a2c1053b49bf18b9986e14be94
--- a/media-libs/libopenshot-audio/libopenshot-audio-0.3.2.ebuild
+++ b/media-libs/libopenshot-audio/libopenshot-audio-0.3.2.ebuild
@ -0,0 +1,24 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Library for audio editing and playback used by OpenShot"
+HOMEPAGE="https://www.openshot.org/"
+SRC_URI="https://github.com/OpenShot/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/8"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="media-libs/alsa-lib
+	media-libs/freetype
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXrandr"
+DEPEND="${RDEPEND}"
--- a/media-libs/libopenshot/Manifest
+++ b/media-libs/libopenshot/Manifest
@ -1 +1,2 @@
 DIST libopenshot-0.3.0.tar.gz 26122831 BLAKE2B 65cadf634b6b7c6da35af64ba96c92fa32ee075966ba3d7f1711210dc784f7e263b01eecdc0c613e529cc501072b8b4a0ee6b297df62fa323ed1fddfc844f874 SHA512 5c72db9c39d2afaecb1c4ebf3192cd8795d4683f2b1210029b99657baf853515b92f392c25b65ea652a71d204a1b172123d264c95f1c3676a612e21f9ca38d2e
+DIST libopenshot-0.3.2.tar.gz 26132237 BLAKE2B 5bc371481ddf69b5de909963cb83d1128066280e1259ae8b23f7ef5450f3da00ef1137dcefe2978e10d1a51931529f104aebdf0601be4b066c7ed371ea43439e SHA512 8891077af28a4db6bc3a7cd078ce5570a8f62e0795c13b0fff795eba60c3e977ece70247033ee4017c9785592355b7421655246a5d6807a5790bd18927739795
--- a/media-libs/libopenshot/libopenshot-0.3.2.ebuild
+++ b/media-libs/libopenshot/libopenshot-0.3.2.ebuild
@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake python-single-r1 toolchain-funcs
+
+DESCRIPTION="Video editing library used by OpenShot"
+HOMEPAGE="https://www.openshot.org/"
+SRC_URI="https://github.com/OpenShot/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/21"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples +imagemagick +opencv +python test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/jsoncpp:0=
+	dev-libs/protobuf:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	>=media-libs/libopenshot-audio-0.3.2:0=
+	media-video/ffmpeg:0=[encode,x264,xvid,vpx,mp3,theora,vorbis]
+	net-libs/cppzmq
+	net-libs/zeromq
+	imagemagick? ( >=media-gfx/imagemagick-7:0=[cxx] )
+	opencv? ( >=media-libs/opencv-4.5.2:=[contrib,contribdnn] )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )
+	python? ( dev-lang/swig )
+	test? (
+		dev-cpp/catch:0
+		dev-libs/unittest++
+	)"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	# https://github.com/OpenShot/libopenshot/issues/17
+	use test || cmake_comment_add_subdirectory tests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_BUNDLED_JSONCPP=ON
+		-DENABLE_MAGICK=$(usex imagemagick)
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_RUBY=OFF # TODO: add ruby support
+		-DENABLE_PYTHON=$(usex python)
+		-DENABLE_TESTS=$(usex test)
+		-DUSE_SYSTEM_JSONCPP=ON
+		$(cmake_use_find_package imagemagick ImageMagick)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+		-DPYTHON_LIBRARY="$(python_get_library_path)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build doc
+}
+
+src_test() {
+	cmake_build test
+}
+
+src_install() {
+	local DOCS=( AUTHORS README.md doc/HW-ACCEL.md )
+	use examples && DOCS+=( examples/ )
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+
+	cmake_src_install
+	use python && python_optimize
+}
--- a/media-video/openshot/Manifest
+++ b/media-video/openshot/Manifest
@ -1 +1,2 @@
 DIST openshot-3.0.0.tar.gz 92552771 BLAKE2B 1e7bd8921a472e4ff62b160d67fcb5a8d8c0e6614a28cce87db5078fae5401c69610bd44801344da55fc4df3c8f973263b75a8567d4372fc350f76dbeec428a1 SHA512 d1115095b34937419d0f08aadacc849768a97ba5d3866a46cb8d416a26ac7fbb754b383c99ea8cb70291bd08cec0343191e71cfdd19c046bbd1a43541fc0673a
+DIST openshot-3.1.1.tar.gz 95843738 BLAKE2B 4059fe12b064692070278366f787789866dcbe39414d10217fb62b671dda98ebb6d2f76b8e1cfe2284a647e3d7ebc460b620ba0756a4542f5b26e7ef669e9b3e SHA512 4e5a42825abf8e3862957039169905a6f03872d81de454f52a57ace2e636e91b2f4e87ae603bf9669baa7d1bbbd6c0213efd0c72e23f2b209ba266af2fbe380f
--- a/media-video/openshot/files/openshot-3.1.1-fix-pybuild.patch
+++ b/media-video/openshot/files/openshot-3.1.1-fix-pybuild.patch
@ -0,0 +1,22 @@
+diff --git a/setup.py b/setup.py
+index ee7a13f..549ecbd 100644
+--- a/setup.py
+++ b/setup.py
+@@ -29,7 +29,7 @@ import os
+ import sys
+ import fnmatch
+ import subprocess
+-from setuptools import setup
+from setuptools import setup, find_namespace_packages
+ from shutil import copytree, rmtree, copy
+ 
+ 
+@@ -105,7 +105,7 @@ package_data["openshot_qt"] = src_files
+ # Call the main Distutils setup command
+ # -------------------------------------
+ dist = setup(
+-    packages=[('openshot_qt')],
+    packages=find_namespace_packages(include=[('openshot_qt*')]),
+     package_data=package_data,
+     data_files=os_files,
+     include_package_data=True,
--- a/media-video/openshot/openshot-3.1.1.ebuild
+++ b/media-video/openshot/openshot-3.1.1.ebuild
@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_REQ_USE=xml
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1 xdg
+
+MY_PN="${PN}-qt"
+
+DESCRIPTION="Award-winning free and open-source video editor"
+HOMEPAGE="https://openshot.org/"
+SRC_URI="https://github.com/OpenShot/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3+"
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="$(python_gen_cond_dep '
+		dev-python/httplib2[${PYTHON_USEDEP}]
+		dev-python/PyQt5[${PYTHON_USEDEP},gui,svg,widgets]
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		dev-python/pyzmq[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	')
+	>=media-libs/libopenshot-0.3.2:0=[python,${PYTHON_SINGLE_USEDEP}]"
+DEPEND=""
+BDEPEND="$(python_gen_cond_dep '
+		doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	')"
+
+PATCHES=( "${FILESDIR}/${P}-fix-pybuild.patch" )
+
+src_prepare() {
+	distutils-r1_python_prepare_all
+	# prevent setup.py from trying to update MIME databases
+	sed -i 's/^ROOT =.*/ROOT = False/' setup.py || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}
+
+python_test() {
+	local -x sitedir=$(python_get_sitedir)
+	local -x PYPATH="${BUILD_DIR}/install/${sitedir}/${PN}_qt/"
+	cd "${PYPATH}"
+	"${EPYTHON}" tests/query_tests.py -v --platform minimal || die
+}