From 9d9beb4a8852cc3b7b2f2f8f458b373685b36bff Mon Sep 17 00:00:00 2001
From: nemofsan <nemofsan@yandex.ru>
Date: Sun, 18 Dec 2022 19:08:42 +0300
Subject: [PATCH] Added gnome-control-center-43.1-r1.ebuild

---
 gnome-base/gnome-control-center/Manifest      |   3 +
 .../gnome-control-center-43.1-r1.ebuild       | 190 ++++++++++++++++++
 profiles/CLDG/package.mask                    |   3 -
 3 files changed, 193 insertions(+), 3 deletions(-)
 create mode 100644 gnome-base/gnome-control-center/gnome-control-center-43.1-r1.ebuild

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index a00dcfa..cbba8ff 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,3 +1,6 @@
 DIST gnome-control-center-42.0-patchset.tar.xz 5932 BLAKE2B 1c9311481be6a07dc2ff61fc9e65f190bc1668026fba2a1e4a8edf9a033e6b2b9019542d89aac4480323ee4802e00b765654008f5252e87040f013a990cb8048 SHA512 b76c1facd3566edcadfe33f81027966da35bb03909bfbae6faad72005b92447e291fa424611196bfae6e1dc5bf5982917f3ae14c36d87206f6bfb4af502bf1a4
 DIST gnome-control-center-42.3.tar.xz 6242028 BLAKE2B 8b757e3286acb2b40732ce601d63be4de0fe0f16fec652e3be83b6c7ed6718d89b6e15608d29ce3f295453510b8986ea410c0de96bb0d9dabb4f3b9c77c2fae5 SHA512 eb82f65b580637fa057196daed836b3ea24a223b9932a2063b2879357f8a62626a6939835dc165a6d3c5706d16b99192301d4de021e68faaabb8d2ecc2a317a3
+DIST gnome-control-center-43.0-patchset.tar.xz 5940 BLAKE2B 91f47272518175286943a160ef77338b0153aa700a75315708ec478627dda8353b21d257b2baed9961ba77700e43c5655be06591b447c442881f828dd7002622 SHA512 e4683e99f43d9c395238df02228a87df4798df53c936bc8d188e366653d9e75b5219b0b0d8eb66ad21141fc2f1a882b994b96cf523c26b8dc21edb854aa1f384
+DIST gnome-control-center-43.1.tar.xz 5702380 BLAKE2B 646342ff6d2384fd5324a01284d4db9459db1982a127ff7c6b107cc6cc8e92cab97dd93adaafacde1e3159f9874a5a652a44da4729e5a2afc18a7fbead624d5e SHA512 aea5d137dbe25b8da13521ebfdff8858aebb210e849e2d93105df5a1d80b41f7221de493c7c343bb4bdcec29a48b9c6ddfbafc24f3ca90a44c6c63e80e5b25e5
 EBUILD gnome-control-center-42.3-r1.ebuild 6099 BLAKE2B 5be3946024796a3607219f7acf27c5081adfc853cf40c5caac50d5ea1156a3bde2297149618553196d5c664403d5933c9ede8ac6ec2e681fdca7c2cca93842da SHA512 c0c5a3a0c4400e4c3aa2f3d15df21f12bc2e117be91ddd15b42e3d6ef168a1550dc226a1a350959075e145006bc260a4701d0ab362a76c1793b4637ee10c8386
+EBUILD gnome-control-center-43.1-r1.ebuild 6278 BLAKE2B 19609ca681ed2349e83d97cae5f09d87b17be989018afa65f7c62abe0ae1f2c48d43d55e15860aedf8e90724fb02e7558fc377333b53791197dbf471827872dd SHA512 2980d7b99a41006f40f2fe428a15ba50c475463f51b21a035128a1d1953b9c0c3287f9e9062dfe4e95e606a27d2353d85fd308aecd2b5e2af710443a903b7375
diff --git a/gnome-base/gnome-control-center/gnome-control-center-43.1-r1.ebuild b/gnome-base/gnome-control-center/gnome-control-center-43.1-r1.ebuild
new file mode 100644
index 0000000..b5850b6
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-43.1-r1.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-control-center"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-43.0-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="amd64 ~arm arm64 ~ppc ~ppc64 ~riscv x86"
+
+# meson.build depends on python unconditionally
+BDEPEND="${PYTHON_DEPS}"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	gnome-online-accounts? (
+		x11-libs/gtk+:3
+		>=net-libs/gnome-online-accounts-3.25.3:=
+	)
+	>=media-libs/libpulse-2.0[glib]
+	>=gui-libs/libadwaita-1.2.0:1
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.70.0:2
+	gnome-base/gnome-desktop:4=
+	>=gnome-base/gnome-settings-daemon-41.0[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-42_alpha
+	dev-libs/libxml2:2
+	>=sys-power/upower-0.99.8:=
+	>=dev-libs/libgudev-232
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	media-libs/libepoxy
+	app-crypt/gcr:0=
+	>=dev-libs/libpwquality-1.2.2
+	>=gui-libs/gtk-4.4:4[X,wayland=]
+	>=sys-auth/polkit-0.114
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=net-libs/libnma-1.8.36
+		>=net-misc/networkmanager-1.24.0[modemmanager]
+		>=net-misc/modemmanager-0.7.990:=
+	)
+	bluetooth? ( net-wireless/gnome-bluetooth:3= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.3.0:=
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	net-libs/gnutls:=
+	media-libs/gsound
+
+	x11-libs/pango
+"
+# media-libs/libcanberra[pulseaudio,sound] needed for Speaker tests in
+# Settings/Sound/Output/Output Device, bug #814110
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	media-libs/libcanberra[pulseaudio,sound]
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? (
+		app-admin/openrc-settingsd
+		sys-auth/elogind
+	)
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper
+	)
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 )
+	)
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+	networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+		x11-apps/setxkbmap
+	)
+"
+
+PATCHES=(
+	# Patches from gnome-43 branch
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		-Dprivileged_group=wheel
+		-Dsnap=false
+		$(meson_use test tests)
+		$(meson_use debug tracing)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+		-Dmalcontent=false # unpackaged
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/profiles/CLDG/package.mask b/profiles/CLDG/package.mask
index ee53edc..27b57af 100644
--- a/profiles/CLDG/package.mask
+++ b/profiles/CLDG/package.mask
@@ -1,6 +1,3 @@
-# gnome-base/gnome-control-center
->=gnome-base/gnome-control-center-43.1
-
 # x11-terms/gnome-terminal
 >=x11-terms/gnome-terminal-3.46.3